home *** CD-ROM | disk | FTP | other *** search
/ A.C.E. 2 / ACE CD 2.iso / FILES / UTILS / AMOSPRO4.DMS / in.adf / Extensions / |Music.s < prev    next >
Encoding:
Text File  |  1992-09-28  |  93.0 KB  |  4,615 lines
  1.  
  2. ;---------------------------------------------------------------------
  3. ;    **   **   **  ***   ***   ****     **    ***  **  ****
  4. ;   ****  *** *** ** ** **     ** **   ****  **    ** **  **
  5. ;  **  ** ** * ** ** **  ***   *****  **  **  ***  ** **
  6. ;  ****** **   ** ** **    **  **  ** ******    ** ** **
  7. ;  **  ** **   ** ** ** *  **  **  ** **  ** *  ** ** **  **
  8. ;  **  ** **   **  ***   ***   *****  **  **  ***  **  ****
  9. ;---------------------------------------------------------------------
  10. ; Music extension source code for AMOSPro, Last change 29/09/1992
  11. ; By Francois Lionet
  12. ; AMOS, AMOSPro AMOS Compiler (c) Europress Software 1990-1992
  13. ; To be used with AMOSPro 1.0 and over
  14. ;--------------------------------------------------------------------- 
  15. ; This file is public domain
  16. ;---------------------------------------------------------------------
  17. ;
  18. Version        MACRO
  19.         dc.b    "1.0"
  20.         ENDM
  21. ;
  22. ;
  23. ; This listing explains how to create an extension for AMOSPro.
  24. ; The AMOSPro compiler will be compatible with these extension.
  25. ;
  26. ;    If you have made an extension for AMOS 1.3, just read the
  27. ; file called New_In_Pro.Asc to know the difference between the
  28. ; extension format. Not many changes, only new equates, and some
  29. ; new functions.
  30. ;
  31. ; >>> What's an extension?
  32. ;
  33. ; An extension to AMOS is a machine language program that adds new 
  34. ; instructions to the already huge AMOS instruction set. This system is
  35. ; designed to be as powerfull as AMOS itself: the extension includes its 
  36. ; own token list, its own routines. It can even access some main AMOS
  37. ; routines via special macros. It has a total access to the internal AMOS 
  38. ; data zone, and to the graphic library functions.
  39. ;
  40. ; To produce your own extension, I suggest you copy and rename this
  41. ; file, and remove the used code. This way you will not forgive one line.
  42. ; Also keep in mind that you can perfectly call AMOS from within MONAM2,
  43. ; and set some ILLEGAL instructions where you want to debug. To flip back to
  44. ; MONAM2 display, just press AMIGA-A.
  45. ;
  46. ; I have designed the extension system so that one only file works with 
  47. ; both AMOS interpretor and compiler. 
  48. ;     - The extension is more a compiler library than a one chunk program:
  49. ;    it is done so that the compiler can pick one routine here and there
  50. ;    to cope with the program it is compiling.
  51. ;    - AMOSPro extension loader works a little like the compiler, exept
  52. ;    that all instructions are loaded and relocated.
  53. ;
  54. ; This code was assembled with GENIM2 on a A3000 25 Mhz machine, but a
  55. ; A500 can do it very well!
  56. ; The assembled program must be ONE CHUNK only, you must not link the 
  57. ; the symbol table with it. Also be sure that you program is totally 
  58. ; relocatable (see later) : if not it will add a relocation chunk to 
  59. ; the output code, and your extension will simply crash AMOS on loading
  60. ; (and the compiler too!).
  61.  
  62. ;
  63. ; Here we go now!
  64. ;
  65. ; Here comes the number of the extension in the list of extensions in
  66. ; AMOSPro_Interpretor_Config program (minus one).
  67. ; This number is used later to reference the extension in internal AMOS 
  68. ; tables...
  69. ;
  70. ExtNb        equ    1-1
  71.  
  72. ; You must include this file, it will decalre everything for you.
  73.         Include    "|AMOS_Includes.s"
  74. ; A usefull macro to find the address of data in the extension's own 
  75. ; datazone (see later)...
  76. DLea        MACRO
  77.         move.l    ExtAdr+ExtNb*16(a5),\2
  78.         add.w    #\1-MB,\2
  79.         ENDM
  80.  
  81. ; Another macro to load the base address of the datazone...
  82. DLoad        MACRO
  83.         move.l    ExtAdr+ExtNb*16(a5),\1
  84.         ENDM
  85.  
  86. ; Now some equates used by the music extension itself. Ignore this in your
  87. ; code!
  88.  
  89. Translate    equ -30
  90.  
  91. *************** Enveloppes definitions
  92.         RsReset
  93. EnvNb:        rs.w    1
  94. EnvDVol:    rs.w    1
  95. EnvVol:        rs.l    1
  96. EnvDelta:    rs.l     1
  97. EnvAd:        rs.l    1
  98. EnvDeb:        rs.l    1
  99. EnvLong:    equ     __Rs
  100.  
  101. *************** Wave definition
  102. LWave:        equ     256+128+64+32+16+8+4+2
  103. LNoise:        equ     LWave
  104.         RsReset
  105. WaveNext:    rs.l    1
  106. WaveNb:        rs.w    1
  107. WaveEnv:    rs.w    16*2
  108. WaveDeb:    rs.b    LWave
  109. WaveLong:    equ     __Rs
  110.  
  111. *************** Music voice data
  112.         RsReset
  113. VoiAdr        rs.l    1
  114. VoiDeb        rs.l    1
  115. VoiInst        rs.l    1
  116. VoiDPat        rs.l    1
  117. VoiPat        rs.l    1
  118. VoiCpt        rs.w    1
  119. VoiRep        rs.w    1
  120. VoiNote        rs.w    1
  121. VoiDVol        rs.w    1
  122. VoiVol        rs.w    1
  123. VoiEffect    rs.l    1
  124. VoiValue    rs.w    1
  125. VoiPToTo    rs.w    1
  126. VoiPTone    rs.b    1
  127. VoiVib        rs.b    1
  128. VoiLong        equ     __Rs
  129.  
  130. *************** MUBASE table
  131.         RsReset
  132. * Voix 0
  133. MuVoix0        equ    __Rs
  134. VoiAdr0        rs.l    1
  135. VoiDeb0        rs.l    1
  136. VoiInst0    rs.l    1
  137. VoiDPat0    rs.l    1
  138. VoiPat0        rs.l    1
  139. VoiCpt0        rs.w    1
  140. VoiRep0        rs.w    1
  141. VoiNote0    rs.w    1
  142. VoiDVol0    rs.w    1
  143. VoiVol0        rs.w    1
  144. VoiEffect0    rs.l    1
  145. VoiValue0    rs.w    1
  146. VoiPToTo0    rs.w    1
  147. VoiPTone0    rs.b    1
  148. VoiVib0        rs.b    1
  149. * Voix 1
  150. MuVoix1        equ    __Rs
  151. VoiAdr1        rs.l    1
  152. VoiDeb1        rs.l    1
  153. VoiInst1    rs.l    1
  154. VoiDPat1    rs.l    1
  155. VoiPat1        rs.l    1
  156. VoiCpt1        rs.w    1
  157. VoiRep1        rs.w    1
  158. VoiNote1    rs.w    1
  159. VoiDVol1    rs.w    1
  160. VoiVol1        rs.w    1
  161. VoiEffect1    rs.l    1
  162. VoiValue1    rs.w    1
  163. VoiPToTo1    rs.w    1
  164. VoiPTone1    rs.b    1
  165. VoiVib1        rs.b    1
  166. * Voix 2
  167. MuVoix2        equ    __Rs
  168. VoiAdr2        rs.l    1
  169. VoiDeb2        rs.l    1
  170. VoiInst2    rs.l    1
  171. VoiDPat2    rs.l    1
  172. VoiPat2        rs.l    1
  173. VoiCpt2        rs.w    1
  174. VoiRep2        rs.w    1
  175. VoiNote2    rs.w    1
  176. VoiDVol2    rs.w    1
  177. VoiVol2        rs.w    1
  178. VoiEffect2    rs.l    1
  179. VoiValue2    rs.w    1
  180. VoiPToTo2    rs.w    1
  181. VoiPTone2    rs.b    1
  182. VoiVib2        rs.b    1
  183. * Voix 3
  184. MuVoix3        equ    __Rs
  185. VoiAdr3        rs.l    1
  186. VoiDeb3        rs.l    1
  187. VoiInst3    rs.l    1
  188. VoiDPat3    rs.l    1
  189. VoiPat3        rs.l    1
  190. VoiCpt3        rs.w    1
  191. VoiRep3        rs.w    1
  192. VoiNote3    rs.w    1
  193. VoiDVol3    rs.w    1
  194. VoiVol3        rs.w    1
  195. VoiEffect3    rs.l    1
  196. VoiValue3    rs.w    1
  197. VoiPToTo3    rs.w    1
  198. VoiPTone3    rs.b    1
  199. VoiVib3        rs.b    1
  200.  
  201. * Other data
  202. MuCpt        rs.w    1
  203. MuTempo        rs.w    1
  204. MuStart        rs.w    1
  205. MuStop        rs.w    1
  206. * Total length
  207. MuLong        equ     __Rs
  208.  
  209. IntEnaR        equ    $1c
  210. IntReqR        equ    $1e
  211. is_data        equ    $0e
  212. is_code        equ    $12
  213. ln_pri        equ    $09
  214. ln_type        equ    $08
  215.  
  216. ; All the above did not produce any byte of code. Here is the real beginning
  217. ; of the program. It MUST begin by a small table of pointers so that both
  218. ; AMOS and the compiler know where to get their data...
  219. ; Please remark that everything is relocatable...
  220.  
  221. ******************************************************************
  222. *    AMOSPro MUSIC EXTENSION
  223. ;
  224. ; First, a pointer to the token list
  225. Start    dc.l    C_Tk-C_Off
  226. ;
  227. ; Then, a pointer to the first library function
  228.     dc.l    C_Lib-C_Tk
  229. ;
  230. ; Then to the title
  231.     dc.l    C_Title-C_Lib
  232. ;
  233. ; From title to the end of the program
  234.     dc.l    C_End-C_Title
  235. ;
  236. ; An important flag. Imagine a program does not call your extension, the 
  237. ; compiler will NOT copy any routine from it in the object program. For 
  238. ; certain extensions, like MUSIC, COMPACT, it is perfect.
  239. ; But for the REQUEST extension, even if it is not called, the first routine 
  240. ; MUST be called, otherwise AMOS requester will not work!
  241. ; So, a value of 0 indicates to copy if needed only,
  242. ; A value of -1 forces the copy of the first library routine...
  243.     dc.w    0    
  244.  
  245. ******************************************************************
  246. *    Offset to library
  247. ;
  248. ; This list contains all informations for the compiler 
  249. ; and AMOS to locate your routines, in a relocatable way.
  250. ; You can produce such tables using the MAKE_LABEL.AMOS utility, found 
  251. ; on this very disc.
  252. ; All labels MUST be in order. The size of each routine MUST BE EVEN,
  253. ; as the size is divided by two. So be carefull to put an EVEN instruction
  254. ; after some text...
  255. ; You easily understand that the size of each routine can reach 128K, 
  256. ; which is largely enough. You can have up to 2000 routines in the list.
  257. ; The main AMOS.Lib library has 1100 labels...
  258.  
  259. C_Off   dc.w (L1-L0)/2,(L2-L1)/2,(L3-L2)/2,(L4-L3)/2
  260.         dc.w (L5-L4)/2,(L6-L5)/2,(L7-L6)/2,(L8-L7)/2
  261.         dc.w (L9-L8)/2,(L10-L9)/2,(L11-L10)/2,(L12-L11)/2
  262.         dc.w (L13-L12)/2,(L14-L13)/2,(L15-L14)/2,(L16-L15)/2
  263.         dc.w (L17-L16)/2,(L18-L17)/2,(L19-L18)/2,(L20-L19)/2
  264.         dc.w (L21-L20)/2,(L22-L21)/2,(L23-L22)/2,(L24-L23)/2
  265.         dc.w (L25-L24)/2,(L26-L25)/2,(L27-L26)/2,(L28-L27)/2
  266.         dc.w (L29-L28)/2,(L30-L29)/2,(L31-L30)/2,(L32-L31)/2
  267.         dc.w (L33-L32)/2,(L34-L33)/2,(L35-L34)/2,(L36-L35)/2
  268.         dc.w (L37-L36)/2,(L38-L37)/2,(L39-L38)/2,(L40-L39)/2
  269.         dc.w (L41-L40)/2,(L42-L41)/2,(L43-L42)/2,(L44-L43)/2
  270.         dc.w (L45-L44)/2,(L46-L45)/2,(L47-L46)/2,(L48-L47)/2
  271.         dc.w (L49-L48)/2,(L50-L49)/2,(L51-L50)/2,(L52-L51)/2
  272.         dc.w (L53-L52)/2,(L54-L53)/2,(L55-L54)/2,(L56-L55)/2
  273.         dc.w (L57-L56)/2,(L58-L57)/2,(L59-L58)/2,(L60-L59)/2
  274.         dc.w (L61-L60)/2,(L62-L61)/2,(L63-L62)/2,(L64-L63)/2
  275.         dc.w (L65-L64)/2,(L66-L65)/2,(L67-L66)/2,(L68-L67)/2
  276.         dc.w (L69-L68)/2,(L70-L69)/2,(L71-L70)/2,(L72-L71)/2
  277.         dc.w (L73-L72)/2,(L74-L73)/2,(L75-L74)/2,(L76-L75)/2
  278.         dc.w (L77-L76)/2,(L78-L77)/2,(L79-L78)/2,(L80-L79)/2
  279.         dc.w (L81-L80)/2,(L82-L81)/2,(L83-L82)/2,(L84-L83)/2
  280.         dc.w (L85-L84)/2,(L86-L85)/2,(L87-L86)/2,(L88-L87)/2
  281.     dc.w (L89-L88)/2,(L90-L89)/2,(L91-L90)/2,(L92-L91)/2
  282.         dc.w (L93-L92)/2,(L94-L93)/2,(L95-L94)/2,(L96-L95)/2
  283.         dc.w (L97-L96)/2,(L98-L97)/2,(L99-L98)/2,(L100-L99)/2
  284.         dc.w (L101-L100)/2,(L102-L101)/2,(L103-L102)/2,(L104-L103)/2
  285.         dc.w (L105-L104)/2,(L106-L105)/2,(L107-L106)/2,(L108-L107)/2
  286.         dc.w (L109-L108)/2,(L110-L109)/2,(L111-L110)/2,(L112-L111)/2
  287.     dc.w (L113-L112)/2,(L114-L113)/2
  288.  
  289. ; Do not forget the LAST label!!!
  290.  
  291. ******************************************************************
  292. *    TOKEN TABLE
  293. ;
  294. ;
  295. ;    
  296. ; This table is the crucial point of the extension! It tells
  297. ; everything the tokenisation process needs to know. You have to 
  298. ; be carefull when writing it!
  299. ;
  300. ; The format is simple:
  301. ;    dc.w    Number of instruction,Number of function
  302. ;    dc.b    "instruction nam","e"+$80,"Param list",-1[or -2]
  303. ;
  304. ;    (1) Number of instruction / function
  305. ;        You must state the one that is needed for this token.
  306. ;               I suggest you keep the same method of referencing the
  307. ;        routines than mine: L_name, this label being defined
  308. ;        in the main program. (If you come from a 1.23 extension,
  309. ;        changing your program is easy: just add L_ before the 
  310. ;        name of each routine.
  311. ;        A -1 means take no routine is called (example a 
  312. ;        instruction only will have a -1 in the function space...)
  313. ;
  314. ;    (2) Instruction name
  315. ;        It must be finished by the letter plus $80. Be carefull
  316. ;        ARGASM assembler produces bad code if you do "a"+$80, 
  317. ;        he wants $80+"a"!!!
  318. ;        - You can SET A MARK in the token table with a "!" before
  319. ;        the name. See later
  320. ;        -Using a $80 ALONE as a name definition, will force AMOS
  321. ;        to point to the previous "!" mark...
  322. ;    
  323. ;    (3) Param list
  324. ;        This list tells AMOS everything about the instruction.
  325. ;
  326. ;    - First character:
  327. ;        The first character defines the TYPE on instruction:
  328. ;            I--> instruction
  329. ;            0--> function that returns a integer
  330. ;            1--> function that returns a float
  331. ;            2--> function that returns a string
  332. ;            V--> reserved variable. In that case, you must
  333. ;                state the type int-float-string
  334. ;    - If your instruction does not need parameters, then you stop
  335. ;    - Your instruction needs parameters, now comes the param list
  336. ;            Type,TypetType,Type...
  337. ;        Type of the parameter (0 1 2)
  338. ;        Comma or "t" for TO
  339. ;
  340. ;    (4) End of instruction
  341. ;            "-1" states the end of the instruction
  342. ;            "-2" tells AMOS that another parameter list
  343. ;                 can be accepted. if so, MUST follow the
  344. ;                 complete instruction definition as explained
  345. ;                 but with another param list.
  346. ;    If so, you can use the "!" and $80 facility not to rewrite the
  347. ;    full name of the instruction...See SAM LOOP ON instruction for an
  348. ;    example...
  349. ;
  350. ;    Remember that AMOS token list comes first, so names like:
  351. ;    PRINTHELLO will never work: AMOS will tokenise PRINT first!
  352. ;    Extension token list are explored in order of number...
  353.  
  354. ; The next two lines needs to be unchanged...
  355. C_Tk:    dc.w     1,0
  356.     dc.b     $80,-1
  357.  
  358. ; Now the real tokens...
  359.     dc.w    -1,L_FMB
  360.     dc.b    "mubas","e"+$80,"0",-1
  361.     dc.w    -1,L_FVu
  362.     dc.b    "vumete","r"+$80,"00",-1
  363.     dc.w    L_IVoice,-1
  364.     dc.b    "voic","e"+$80,"I0",-1
  365.     dc.w    L_IMusOff,-1
  366.     dc.b    "music of","f"+$80,"I",-1
  367.     dc.w    L_IMuStop,-1
  368.     dc.b    "music sto","p"+$80,"I",-1
  369.     dc.w    L_ITempo,-1
  370.     dc.b    "temp","o"+$80,"I0",-1
  371.     dc.w    L_IMusic,-1
  372.     dc.b    "musi","c"+$80,"I0",-1
  373.  
  374.     dc.w    L_INoTo,-1
  375.     dc.b    "noise t","o"+$80,"I0",-1
  376.     dc.w    L_Boom,-1
  377.     dc.b     "boo","m"+$80,"I",-1
  378.     dc.w    L_Shoot,-1
  379.     dc.b    "shoo","t"+$80,"I",-1
  380.     dc.w    L_ISBank,-1
  381.     dc.b    "sam ban","k"+$80,"I0",-1
  382.     dc.w    L_ISLOn0,-1
  383.     dc.b    "!sam loop o","n"+$80,"I",-2
  384.     dc.w    L_ISLOn1,-1
  385.     dc.b    $80,"I",-1
  386.     dc.w    L_ISLOf0,-1
  387.     dc.b    "sam loop of","f"+$80,"I",-2
  388.     dc.w    L_ISLOf1,-1
  389.     dc.b    $80,"I0",-1
  390.     dc.w    L_ISamTo,-1
  391.     dc.b    "sampl","e"+$80,"I0t0",-1
  392.     dc.w     L_ISam1,-1
  393.     dc.b     "!sam pla","y"+$80,"I0",-2
  394.     dc.w    L_ISam2,-1
  395.     dc.b    $80,"I0,0",-2
  396.     dc.w     L_ISam3,-1
  397.     dc.b    $80,"I0,0,0",-1 
  398.     dc.w     L_ISamR,-1
  399.     dc.b     "sam ra","w"+$80,"I0,0,0,0",-1    
  400.     dc.w    L_Bell0,-1
  401.     dc.b     "!bel","l"+$80,"I",-2
  402.     dc.w     L_Bell1,-1
  403.     dc.b    $80,"I0",-1
  404.     dc.w    L_IPlOf0,-1
  405.     dc.b    "!play of","f"+$80,"I",-2
  406.     dc.w    L_IPlOf1,-1
  407.     dc.b    $80,"I0",-1
  408.     dc.w     L_IPlay2,-1
  409.     dc.b    "!pla","y"+$80,"I0,0",-2
  410.     dc.w    L_IPlay3,-1
  411.     dc.b    $80,"I0,0,0",-1
  412.     dc.w     L_ISWave,-1
  413.     dc.b     "set wav","e"+$80,"I0,2",-1
  414.     dc.w    L_IDWave1,-1
  415.     dc.b    "del wav","e"+$80,"I0",-1
  416.     dc.w    L_ISEnv,-1
  417.     dc.b    "set enve","l"+$80,"I0,0t0,0",-1
  418.     dc.w    L_IMVol,-1
  419.     dc.b    "mvolum","e"+$80,"I0",-1
  420.     dc.w     L_IVol1,-1
  421.     dc.b    "!volum","e"+$80,"I0",-2
  422.     dc.w     L_IVol2,-1
  423.     dc.b    $80,"I0,0",-1
  424.     dc.w    L_IWave,-1
  425.     dc.b     "wav","e"+$80,"I0t0",-1
  426.     dc.w    L_LedOn,-1
  427.     dc.b    "led o","n"+$80,"I",-1
  428.     dc.w    L_LedOf,-1
  429.     dc.b    "led of","f"+$80,"I",-1
  430.     dc.w    L_ISay1,-1
  431.     dc.b    "!sa","y"+$80,"I2",-2
  432.     dc.w    L_ISay2,-1
  433.     dc.b    $80,"I2,0",-1
  434.     dc.w    L_ITalk,-1
  435.     dc.b    "set tal","k"+$80,"I0,0,0,0",-1
  436.     dc.w    L_SLoad,-1
  437.     dc.b    "sloa","d"+$80,"I0t0,0",-1
  438.     dc.w    -1,L_Samswapped
  439.     dc.b    "sam swappe","d"+$80,"00",-1
  440.     dc.w    L_SamSwap,-1
  441.     dc.b    "sam swa","p"+$80,"I0t0,0",-1
  442.     dc.w     L_SamStop0,-1
  443.     dc.b    "!sam sto","p"+$80,"I",-2
  444.     dc.w    L_SamStop1,-1
  445.     dc.b    $80,"I0",-1
  446.  
  447.     dc.w    L_TrackStop,-1
  448.     dc.b    "track sto","p"+$80,"I",-1
  449.     dc.w    L_TrackLoopon,-1
  450.     dc.b    "track loop o","n"+$80,"I",-1
  451.     dc.w    L_TrackLoopof,-1
  452.     dc.b    "track loop o","f"+$80,"I",-1
  453.     dc.w    L_TrackPlay0,-1
  454.     dc.b    "!track pla","y"+$80,"I",-2
  455.     dc.w    L_TrackPlay1,-1
  456.     dc.b    $80,"I0",-2
  457.     dc.w    L_TrackPlay2,-1
  458.     dc.b    $80,"I0,0",-1
  459.     dc.w    L_TrackLoad,-1
  460.     dc.b    "track loa","d"+$80,"I2,0",-1
  461.     
  462.     dc.w    -1,L_LipsX
  463.     dc.b    "mouth widt","h"+$80,"0",-1
  464.     dc.w    -1,L_LipsY
  465.     dc.b    "mouth heigh","t"+$80,"0",-1
  466.     dc.w    L_Lips,-1
  467.     dc.b    "mouth rea","d"+$80,"I",-1
  468.     dc.w    L_NarStop,-1
  469.     dc.b    "talk sto","p"+$80,"I",-1
  470.     dc.w    L_TalkMisc,-1
  471.     dc.b    "talk mis","c"+$80,"I0,0",-1
  472.  
  473.     dc.w    L_SSave,-1
  474.     dc.b    "ssav","e"+$80,"I0,0t0",-1
  475.  
  476.     dc.w    L_MedLoad,-1
  477.     dc.b    "med loa","d"+$80,"I2,0",-1
  478.     dc.w    L_MedPlay0,-1
  479.     dc.b    "!med pla","y"+$80,"I",-2
  480.     dc.w    L_MedPlay1,-1
  481.     dc.b    $80,"I0",-2
  482.     dc.w    L_MedPlay2,-1
  483.     dc.b    $80,"I0,0",-1
  484.     dc.w    L_MedStop,-1
  485.     dc.b    "med sto","p"+$80,"I",-1
  486.     dc.w    L_MedCont,-1
  487.     dc.b    "med con","t"+$80,"I",-1
  488.     dc.w    L_MedMidiOn,-1
  489.     dc.b    "med midi o","n"+$80,"I",-1
  490.     dc.w     0
  491.  
  492. ;
  493. ; Now come the big part, the library. Every routine is delimited by the
  494. ; two labels: L(N) and L(N+1).
  495. ; AMOS loads the whole extension, but the compiler works differently:
  496. ; The compiler picks each routine in the library and copy it into the
  497. ; program, INDIVIDUALLY. It means that you MUST NEVER perform a JMP, a
  498. ; BSR or get an address from one library routine to another: the distance
  499. ; between them may change!!! Use the special macros instead...
  500. ;
  501. ; Importants points to follow: 
  502. ;
  503. ;    - Your code must be (pc), TOTALLY relocatable, check carefully your
  504. ;      code!
  505. ;    - You cannot directly call other library routines from one routine
  506. ;    by doing a BSR, but I have defined special macros (in S_CEQU file) 
  507. ;    to allow you to easily do so. Here is the list of available macros:
  508. ;
  509. ;    RBsr    L_Routine    does a simple BSR to the routine
  510. ;    RBra    L_Routine    as a normal BRA
  511. ;    RBeq    L_Routine    as a normal Beq
  512. ;    RBne    L_Routine    ...
  513. ;    RBcc    L_Routine
  514. ;    RBcs    L_Routine
  515. ;    RBlt    L_Routine
  516. ;    RBge    L_Routine
  517. ;    RBls    L_Routine
  518. ;    RBhi    L_Routine
  519. ;    RBle    L_Routine
  520. ;    RBpl    L_Routine
  521. ;    RBmi    L_Routine
  522. ;
  523. ; I remind you that you can only use this to call an library routine
  524. ; from ANOTHER routine. You cannot do a call WITHIN a routine, or call
  525. ; the number of the routine your caling from...
  526. ; The compiler (and AMOSPro extension loading part) will manage to find
  527. ; the good addresses in your program from the offset table.
  528. ;
  529. ; You can also call some main AMOS.Lib routines, to do so, use the 
  530. ; following macros:
  531. ;
  532. ;    RJsr    L_Routine    
  533. ;    RJmp    L_Routine    
  534. ; 
  535. ; 
  536. ; As you do not have access any more to the small table with jumps to the
  537. ; routines within AMOS, here is the concordance of the routines (the numbers
  538. ; are just refecrences to the old AMOS 1.23 calling table, and is not of
  539. ; any use in AMOS1.3):
  540. ;
  541. ;
  542. ;    RJsr    L_Error
  543. ; ~~~~~~~~~~~~~~~~~~~~~
  544. ;    Jump to normal error routine. See end of listing
  545. ;
  546. ;    RJsr    L_ErrorExt
  547. ; ~~~~~~~~~~~~~~~~~~~~~~~~
  548. ;    Jump to specific error routine. See end of listing.
  549. ;
  550. ;     RJsr    L_Tests
  551. ; ~~~~~~~~~~~~~~~~~~~~~
  552. ;    Perform one AMOSPro updating procedure, update screens, sprites,
  553. ;    bobs etc. You should use it for wait loops.
  554. ;
  555. ;    RJsr    L_WaitRout
  556. ; ~~~~~~~~~~~~~~~~~~~~~~~~
  557. ;    See play instruction.
  558. ;
  559. ;    RJsr    L_GetEc
  560. ; ~~~~~~~~~~~~~~~~~~~~~
  561. ;    Get screen address: In: D0.l= number, Out: A0=address
  562. ;
  563. ;    RJsr    L_Demande
  564. ; ~~~~~~~~~~~~~~~~~~~~~~~
  565. ;    Ask for string space.
  566. ;    D3.l is the length to ask for. Return A0/A1 point to free space.
  567. ;    Poke your string there, add the length of it to A0, EVEN the 
  568. ;    address to the highest multiple of two, and move it into
  569. ;    HICHAINE(a5) location...
  570. ;
  571. ;    RJsr    L_RamChip
  572. ; ~~~~~~~~~~~~~~~~~~~~~
  573. ;    Ask for PUBLIC|CLEAR|CHIP ram, size D0, return address in D0, nothing
  574. ;    changed, Z set according to the success.
  575. ;
  576. ;    RJsr    L_RamChip2
  577. ; ~~~~~~~~~~~~~~~~~~~~~~
  578. ;    Same for PUBLIC|CHIP
  579. ;
  580. ;    RJsr    L_RamFast
  581. ; ~~~~~~~~~~~~~~~~~~~~~
  582. ;    Same for PUBLIC|CLEAR
  583. ;
  584. ;    RJsr    L_RamFast2
  585. ; ~~~~~~~~~~~~~~~~~~~~~~~~
  586. ;    Same for PUBLIC
  587. ;
  588. ;    RJsr    L_RamFree
  589. ; ~~~~~~~~~~~~~~~~~~~~~~~
  590. ;    Free memory A1/D0
  591. ;
  592. ;    RJsr    L_Bnk.OrAdr
  593. ; ~~~~~~~~~~~~~~~~~~~~~~~~~
  594. ;    Find whether a number is a address or a    memory bank number
  595. ;    IN:     D0.l= number 
  596. ;    OUT:     D0/A0= number or start(number)
  597. ;
  598. ;    RJsr    L_Bnk.GetAdr
  599. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~
  600. ;    Find the start of a memory bank.
  601. ;    IN:    D0.l=    Bank number
  602. ;    OUT:    A0=    Bank address
  603. ;        D0.w=    Bank flags
  604. ;        Z set if bank not defined.
  605. ;
  606. ;    RJsr    L_Bnk.GetBobs
  607. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~
  608. ;    Returns the address of the bob's bank
  609. ;    IN:
  610. ;    OUT:    Z     Set if not defined
  611. ;        A0=    address of bank
  612. ;
  613. ;    RJsr    L_Bnk.GetIcons
  614. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  615. ;    Returns the address of the icons bank
  616. ;    IN:
  617. ;    OUT:    Z     Set if not defined
  618. ;        A0=    address of bank
  619. ;
  620. ;    RJsr    L_Bnk.Reserve
  621. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~
  622. ;    Reserve a memory bank.
  623. ;    IN:    D0.l    Number
  624. ;        D1    Flags
  625. ;        D2    Length
  626. ;        A0    Name of the bank (8 bytes)
  627. ;    OUT:    Z     Set inf not successfull
  628. ;        A0    Address of bank
  629. ;    FLAGS:    
  630. ;        Bnk_BitData        Data bank
  631. ;        Bnk_BitChip        Chip bank
  632. ;        Example:    Bset    #Bnk_BitData|Bnk_BitChip,d1
  633. ;    NOTE:     you should call L_Bnk.Change after reserving/erasing a bank.
  634. ;
  635. ;    RJsr    L_Bnk.Eff
  636. ; ~~~~~~~~~~~~~~~~~~~~~~~
  637. ;    Erase one memory bank.
  638. ;    IN:    D0.l    Number
  639. ;    OUT:    
  640. ;
  641. ;    RJsr    L_Bnk.EffA0
  642. ; ~~~~~~~~~~~~~~~~~~~~~~~~~
  643. ;    Erase a bank from its address.
  644. ;    IN:    A0    Start(bank)
  645. ;    OUT:    
  646. ;
  647. ;    RJsr    L_Bnk.EffTemp
  648. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~
  649. ;    Erase all temporary banks
  650. ;    IN:
  651. ;    OUT:
  652. ;
  653. ;    RJsr    L_Bnk.EffAll
  654. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~
  655. ;    Erase all banks
  656. ;    IN:
  657. ;    OUT:
  658. ;
  659. ;    RJsr    L_Bnk.Change
  660. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~
  661. ;    Inform the extension, the bob handler that something has changed
  662. ;    in the banks. You should use this function after every bank
  663. ;    reserve / erase.
  664. ;    IN:
  665. ;    OUT:
  666. ;
  667. ;     RJsr    L_Dsk.PathIt
  668. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~
  669. ;    Add the current AMOS path to a file name.
  670. ;    IN:    (Name1(a5)) contains the name, finished by zero
  671. ;    OUT:    (Name1(a5)) contains the name with new path
  672. ;    Example:
  673. ;        move.l    Name1(a5),a0
  674. ;        move.l    #"Kiki",(a0)+
  675. ;        clr.b    (a0)
  676. ;        RJsr    L_Dsk.PathIt
  677. ;        ... now I load in the current directory
  678. ;
  679. ;    RJsr     L_Dsk.FileSelector
  680. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  681. ;    Call the file selector.
  682. ;    IN:    12(a3)    Path+filter
  683. ;        8(a3)    Default name
  684. ;        4(a3)    Title 2
  685. ;        0(a3)    Title 1
  686. ;        All strings must be in AMOS string format:
  687. ;            dc.w    Length
  688. ;            dc.b     "String"
  689. ;    OUT:    D0.w    Length of the result. 0 if no selection
  690. ;        A0    Address of first character of the result.
  691.  
  692. ;
  693. ;    HOW DOES IT WORK?
  694. ;
  695. ; Having a look at the |CEQU file, you see that I use special codes
  696. ; to show the compiler that it has to copy the asked routine and relocate
  697. ; the branch. Some remarks:
  698. ;    - The size of a Rbsr is 4 bytes, like the normal branch, it does
  699. ; not change the program (you can make some jumps over it)
  700. ;    - Although I have coded the signal, and put a lot a security, 
  701. ; a mischance may lead to the compiler thinking there is a RBsr where
  702. ; there is nothing than normal data. The result may be disastrous! So if
  703. ; you have BIG parts of datas in which you do not make any special calls,
  704. ; you can put before it the macro: RDATA. It tells the compiler that 
  705. ; the following code, up to the end of the library routine (up to the next
  706. ; L(N) label) is normal data: the compiler will not check for RBranches...
  707. ; Up to now, I have not been forced to do so, but if something goes wrong,
  708. ; try that!
  709. ;
  710. ;
  711.  
  712. C_Lib
  713. ******************************************************************
  714. *        COLD START
  715. *
  716. ; The first routine of the library will perform all initialisations in the
  717. ; booting of AMOS.
  718. ;
  719. ; I have put here all the music datazone, and all the interrupt routines.
  720. ; I suggest you put all you C-Code here too if you have some...
  721.  
  722. ; ALL the following code, from L0 to L1 will be copied into the compiled 
  723. ; program (if any music is used in the program) at once. All RBSR, RBRA etc
  724. ; will be detected and relocated. AMOSPro extension loader does the same.
  725.  
  726. L0    movem.l    a3-a6,-(sp)
  727. ;
  728. ; Here I store the address of the extension data zone in the special area
  729.     lea    MB(pc),a3
  730.     move.l    a3,ExtAdr+ExtNb*16(a5)
  731. ;
  732. ; Here, I store the address of the routine called by DEFAULT, or RUN
  733.     lea    MusDef(pc),a0
  734.     move.l    a0,ExtAdr+ExtNb*16+4(a5)
  735. ;
  736. ; Here, the address of the END routine,
  737.     lea    MusEnd(pc),a0
  738.     move.l    a0,ExtAdr+ExtNb*16+8(a5)
  739. ;
  740. ; And now the Bank check routine..
  741.     lea    BkCheck(pc),a0
  742.     move.l    a0,ExtAdr+ExtNb*16+12(a5)
  743.  
  744. ; You are not obliged to store something in the above areas, you can leave
  745. ; them to zero if no routine is to be called...
  746. ;
  747. ; In AMOS data zone, stands 8 long words allowing you to simply
  748. ; put a patch in the VBL interrupt. The first on is at VBLRout.
  749. ; At each VBL, AMOS explores this list, and call all address <> 0
  750. ; It stops at the FIRST zero. The music patch is the first routine
  751. ; called.
  752.  
  753.     lea    MusInt(pc),a0        * Interrupt routine
  754.     move.l    a0,VBLRout(a5)
  755. ; 50/60 herz?
  756.     move.l    #3546895,MusClock-MB(a3)
  757.     move.w    #100,TempoBase-MB(a3)
  758.     EcCall    NTSC            * Is system NTSC?
  759.     tst.w    d1
  760.     beq.s    ItsPAL
  761.     move.w    #120,TempoBase-MB(a3)
  762.     move.l    #3579545,MusClock-MB(a3)
  763. ItsPAL    
  764. ; Install sample interrupts
  765.     lea    Sami_handler(pc),a0
  766.     move.l    a0,Sami_handad-MB(a3)
  767.  
  768. ; As you can see, you MUST preserve A3-A6, and return in D0 the 
  769. ; Number of the extension if everything went allright. If an error has
  770. ; occured (no more memory, no file found etc...), return -1 in D0 and
  771. ; AMOS will refuse to start.
  772.     movem.l    (sp)+,a3-a6
  773.     moveq    #ExtNb,d0        * NO ERRORS
  774.      rts
  775.  
  776. ******* SCREEN RESET
  777. ; This routine is called each time a DEFAULT occurs...
  778. ;
  779. ; The next instruction loads the internal datazone address. I could have
  780. ; of course done a load MB(pc),a3 as the datazone is in the same
  781. ; library chunk. 
  782.  
  783. MusDef    DLoad    a3    
  784. * Stop/Init narrator
  785.     Rbsr    L_NarStop
  786.     Rbsr    L_NarInit
  787. * Reset TRACKER music
  788.     Rbsr    L_TrackStop
  789. * Reset MED music
  790.     Rbsr    L_MedClose
  791.     clr.b    Med_Midi-MB(a3)
  792. * Reset Sam_interrupts
  793.     move.w    #$000F,Circuits+DmaCon
  794.     Rbsr    L_Sami_install
  795. * Init musique
  796.     Rbsr    L_RazWave        * Reset waves
  797.     move.l    Buffer(a5),a0        * Draw square wave
  798.     move.l    a0,a1
  799.     moveq    #127,d0
  800. MuDf1    move.b    #-127,128(a0)
  801.     move.b    #127,(a0)+
  802.     dbra    d0,MuDf1
  803.     moveq    #0,d1            * 0-> Noise
  804.     Rbsr    L_NeWave
  805.     moveq    #1,d1            * 1-> Square wave
  806.     Rbsr    L_NeWave
  807.     move.w    #LNoise/2-1,d2        * Draw first noise
  808.     move.w    BSeed-MB(a3),d1
  809.     move.l    WaveBase-MB(a3),a0
  810.     lea    WaveDeb(a0),a0
  811. MuDf2    add.w    Circuits+6,d1
  812.     mulu    #$3171,d1
  813.     lsr.l    #8,d1
  814.     move.w    d1,(a0)+
  815.     dbra    d2,MuDf2
  816.     move.w    d1,BSeed-MB(a3)
  817.     moveq    #56,d0            * Default settings
  818.     moveq    #%1111,d1
  819.     Rbsr    L_Vol
  820.     Rbsr    L_MVol
  821.     move.w    #5,SamBank-MB(a3)    * Sample bank=5    
  822.     moveq    #-1,d0            * Sam loop off
  823.     moveq    #-1,d1
  824.     Rbsr    L_SL0
  825.     Rbra    L_MuInit
  826.  
  827. ******* QUIT
  828. ; This routine is called when you quit AMOS or when the compiled program
  829. ; ends. If you have opend devices, reserved memory you MUST close and
  830. ; restore everything to normal.
  831.  
  832. MusEnd:    DLoad    a3
  833.  
  834. ; Ferme le narrator
  835.     Rbsr    L_NarStop
  836.     move.l    $4.w,a6
  837.     move.l    WriteIo-MB(a3),d0
  838.     beq.s    .Skip1
  839.     move.l    d0,a1
  840.     move.l    WriteIo-MB(a3),a1
  841.     jsr    _LVOCloseDevice(a6)
  842. ; Enleve la structure
  843.     move.l    WriteIo-MB(a3),-(sp)
  844.     moveq    #3,d0
  845.     Rbsr    L_Amiga.Lib
  846.     addq.l    #4,sp
  847. ; Enleve les ports
  848.     move.l    WritePort-MB(a3),-(sp)
  849.     moveq    #1,d0
  850.     Rbsr    L_Amiga.Lib
  851.     addq.l    #4,sp
  852.     move.l    ReadPort-MB(a3),-(sp)
  853.     moveq    #1,d0
  854.     Rbsr    L_Amiga.Lib
  855.     addq.l    #4,sp
  856. ; Enleve le translator
  857. .Skip1    move.l    TranBase-MB(a3),d0
  858.     beq.s    NarEnd
  859.     move.l    d0,a1
  860.     jsr    CloseLib(a6)
  861. NarEnd    
  862. * No more TRACKER music
  863.     Rbsr    L_TrackStop
  864. * No more MED music
  865.     Rbsr    L_MedClose
  866. * No more VBL
  867.     clr.l    VBLRout(a5)
  868. * No more Sami
  869.     RBsr    L_Sami_remove
  870. * End music
  871.     Rbsr    L_MOff
  872.     moveq    #%1111,d0
  873.     Rbsr    L_EnvOff
  874.     Rbsr    L_RazWave
  875.     lea    Circuits,a0
  876.     move.w    #$000F,DmaCon(a0)
  877.     clr.w    $a8(a0)
  878.     clr.w    $b8(a0)
  879.     clr.w    $c8(a0)
  880.     clr.w    $d8(a0)
  881. * Finished!
  882.     rts
  883.  
  884. ******* LOOK FOR MUSIC BANK
  885. ; This routine is called after any bank has been loaded, reserved or erased.
  886. ; Here, if a music is being played and if the music bank is erased, I MUST
  887. ; stop the music, otherwise it might crash the computer. That's why I
  888. ; do a checksum on the first bytes of the bank to see if they have changed...
  889. BkCheck    
  890.     Rbsr    L_TrackCheck        * Check Tracker
  891.     Rbsr    L_MedCheck        * Check Med
  892. * Check normal music.
  893.     DLoad    a3
  894.     move.l    MusBank-MB(a3),d2    Old music bank address
  895.     moveq    #3,d0            Ask for music bank address
  896.     Rjsr    L_Bnk.GetAdr
  897.     beq.s    BkNo
  898.     move.l    -8(a0),d0        Looks for "Musi"
  899.     cmp.l    BkMus-MB(a3),d0
  900.     bne.s    BkNo
  901.     moveq    #0,d0            Performs a check sum
  902.     add.l    (a0),d0
  903.     add.l    4(a0),d0
  904.     add.l    8(a0),d0
  905.     add.l    12(a0),d0
  906.     cmp.l    d2,a0
  907.     bne.s    BkNew
  908.     cmp.l    MusCheck-MB(a3),d0
  909.     bne.s    BkNew
  910. * Same bank! Do nothing!
  911.     rts
  912. * No more bank!
  913. BkNo    tst.l    d2
  914.     beq.s    BkNo1
  915.     Rbsr    L_MuInit
  916.     clr.l    MusBank-MB(a3)
  917. BkNo1    rts
  918. * A NEW bank
  919. BkNew    move.l    a0,MusBank-MB(a3)
  920.     move.l    d0,MusCheck-MB(a3)
  921.     Rbsr    L_MuInit
  922.     move.l    MusBank-MB(a3),a0
  923.     move.l    a0,a1
  924.     add.l    (a0),a1
  925.     move.l    a1,BankInst-MB(a3)
  926.     move.l    a0,a1
  927.     add.l    4(a0),a1
  928.     move.l    a1,BankSong-MB(a3)
  929.     add.l    8(a0),a0
  930.     move.l    a0,BankPat-MB(a3)
  931.     rts
  932.  
  933. ***********************************************************
  934. *
  935. *    INTERRUPT ROUTINES
  936. *
  937. ***********************************************************    
  938.  
  939. ******* Sami interrupt handlers
  940. Sami_handler
  941.     add.w    Sami_reg(a1),a0
  942.     move.l    Sami_pos(a1),d0
  943.     cmp.l    Sami_long(a1),d0
  944.     bcc.s    .whatnow
  945. * Poursuit la lecture du sample
  946. .samloop
  947.     move.l    d0,d1
  948.     add.l    #Sami_lplay,d1
  949.     cmp.l    Sami_long(a1),d1
  950.     bls.s    .skip
  951.     move.l    Sami_long(a1),d1
  952. .skip    move.l    d1,Sami_pos(a1)
  953.     sub.l    d0,d1
  954.     lsr.l    #1,d1
  955.     add.l    Sami_adr(a1),d0
  956.     move.l    d0,(a0)                * AUDxLOC
  957.     move.w    d1,4(a0)            * AUDxLEN
  958.     move.w    Sami_dvol(a1),d0
  959.     bmi.s    .skip1
  960.     move.w    d0,8(a0)            * AUDxVOL
  961. .skip1    move.w    Sami_bit(a1),Circuits+IntReq
  962.     rts
  963. * Sample termine. Que faire?
  964. .whatnow
  965.     move.l    d0,d1
  966.     move.l    Sami_radr(a1),d0        * Double buffer?
  967.     bne.s    .swap
  968.     move.l    Sami_rpos(a1),d0        * Boucler?
  969.     bpl.s    .samloop
  970.     bset    #7,Sami_pos(a1)            * Attend?
  971.     tst.l    d1
  972.     bpl.s    .skip1
  973. * Fin du sample-> met du blanc!
  974.     move.w    #0,$a(a0)
  975.     move.w    Sami_dma(a1),d0
  976.     moveq    #0,d1
  977.     bset    d0,d1
  978.     move.w    d1,Circuits+DmaCon
  979.     tst.w    Sami_dvol(a1)
  980.     bmi.s    .skip2
  981.     lea    MB(pc),a0            * Restart music
  982.     bset    d0,MuReStart+1-MB(a0)
  983. .skip2    move.w    Sami_bit(a1),Circuits+IntEna    * No more interrupts
  984.     move.w    Sami_bit(a1),Circuits+IntReq
  985.     rts
  986. * Change de buffer
  987. .swap    clr.l    Sami_radr(a1)
  988.     move.l    d0,Sami_adr(a1)
  989.     move.l    Sami_rlong(a1),Sami_long(a1)
  990.     moveq    #0,d0
  991.     bra    .samloop
  992.  
  993. ******* VBL Entry
  994. MusInt    lea    MB(pc),a3    
  995.     move.w    EnvOn-MB(a3),d0
  996.     beq    Music
  997.     lea    EnvBase-MB(a3),a0
  998.     lea    $a0(a6),a2
  999.     moveq    #0,d1
  1000.     moveq    #3,d2
  1001.     moveq    #0,d5
  1002. MuInt1    btst    d1,d0
  1003.     beq.s    MuIntN
  1004.     move.l    EnvDelta(a0),d3
  1005.     add.l    EnvVol(a0),d3
  1006.     move.l    d3,EnvVol(a0)
  1007.     swap    d3
  1008.     move.w    d3,8(a2)
  1009. MuInt2    subq.w    #1,EnvNb(a0)
  1010.     bne.s    MuIntN
  1011.     Rbsr    L_MuIntE
  1012. MuIntN    lea    EnvLong(a0),a0
  1013.     lea    $10(a2),a2
  1014.     addq.w    #1,d1
  1015.     dbra    d2,MuInt1
  1016.     move.w    d0,EnvOn-MB(a3)
  1017.     move.w    d5,DmaCon(a6)
  1018.     lsl.w    #7,d5
  1019.     move.w    d5,IntEna(a6)
  1020. ******* Make noise?
  1021.     tst.w    Noise-MB(a3)
  1022.     beq.s    Music
  1023.     move.w    PNoise-MB(a3),d0
  1024.     moveq    #7,d2
  1025.     move.w    BSeed-MB(a3),d1
  1026.     move.l    WaveBase-MB(a3),a0
  1027. INoi1    add.w    6(a6),d1
  1028.     mulu    #$3171,d1
  1029.     lsr.l    #8,d1
  1030.     move.w    d1,WaveDeb(a0,d0.w)
  1031.     subq.w    #2,d0
  1032.     bpl.s    INoi2
  1033.     move.w    #LNoise-2,d0
  1034. INoi2    dbra    d2,INoi1
  1035.     move.w    d0,PNoise-MB(a3)
  1036.     move.w    d1,BSeed-MB(a3)
  1037.  
  1038. *******    Music routine
  1039. Music:    move.l    MuBase-MB(a3),d0
  1040.     beq    Tracker
  1041.     movem.l    a4-a6,-(sp)
  1042.     move.l    d0,a5
  1043.     bsr    MuEvery
  1044. * Here is a smart counter, which gives progressive results
  1045. * from zero to 100(PAL), 120(NTSC)...
  1046.     move.w    MuCpt(a5),d0
  1047.     add.w    MuTempo(a5),d0
  1048.     move.w    d0,MuCpt(a5)
  1049.     move.w    TempoBase-MB(a3),d1
  1050.     cmp.w    d1,d0
  1051.     bcs    MuEff
  1052.     sub.w    d1,MuCpt(a5)
  1053. * Lets go for one step of music!
  1054.     moveq    #0,d5
  1055.     moveq    #0,d7
  1056.     move.l    a5,a4
  1057.  
  1058.     tst.b    VoiCpt+1(a4)
  1059.     beq.s    Mus0
  1060.     addq.w    #1,d5
  1061.     subq.b    #1,VoiCpt+1(a4)
  1062.     bne.s    Mus0
  1063.     moveq    #0,d6
  1064.     move.l    MuChip0-MB(a3),a6
  1065.     bsr    MuStep
  1066. Mus0    
  1067.     lea    MuVoix1(a5),a4
  1068.     tst.b    VoiCpt+1(a4)
  1069.     beq.s    Mus1
  1070.     addq.w    #1,d5
  1071.     subq.b    #1,VoiCpt+1(a4)
  1072.     bne.s    Mus1
  1073.     moveq    #1,d6
  1074.     move.l    MuChip1-MB(a3),a6
  1075.     bsr    MuStep
  1076. Mus1
  1077.     lea    MuVoix2(a5),a4
  1078.     tst.b    VoiCpt+1(a4)
  1079.     beq.s    Mus2
  1080.     addq.w    #1,d5
  1081.     subq.b    #1,VoiCpt+1(a4)
  1082.     bne.s    Mus2
  1083.     moveq    #2,d6
  1084.     move.l    MuChip2-MB(a3),a6
  1085.     bsr    MuStep
  1086. Mus2    
  1087.     lea    MuVoix3(a5),a4
  1088.     tst.b    VoiCpt+1(a4)
  1089.     beq.s    Mus3
  1090.     addq.w    #1,d5
  1091.     subq.b    #1,VoiCpt+1(a4)
  1092.     bne.s    Mus3
  1093.     moveq    #3,d6
  1094.     move.l    MuChip3-MB(a3),a6
  1095.     bsr    MuStep
  1096. Mus3    
  1097.     and.w    MuDMAsk-MB(a3),d7
  1098.     move.w    d7,$DFF096
  1099.     tst.w    d5
  1100.     beq.s    MuFin
  1101.     bne.s    MuEnd
  1102. MuEff    bsr    DoEffects
  1103. MuEnd    movem.l    (sp)+,a4-a6
  1104. MuEnd1    rts
  1105. * Finished?
  1106. MuFin    subq.w    #1,MuNumber-MB(a3)
  1107.     beq    MuFini
  1108. * Restarts previous music
  1109.     move.w    MuNumber-MB(a3),d0
  1110.     subq.w    #1,d0
  1111.     mulu    #MuLong,d0
  1112.     lea    MuBuffer-MB(a3),a0
  1113.     add.w    d0,a0
  1114.     move.l    a0,MuBase-MB(a3)
  1115.     move.w    MuDMAsk-MB(a3),MuReStart-MB(a3)
  1116.     clr.w    MuStart(a0)
  1117.     clr.w    MuStop(a0)
  1118.     bra.s    MuEnd
  1119. * Really finished!
  1120. MuFini    clr.l    MuBase-MB(a3)
  1121.     Rbsr    L_MOff
  1122.     bra.s    MuEnd
  1123.  
  1124. ******* One step of music for one voice
  1125. MuStep    lea    MuJumps(pc),a1
  1126.     move.l    VoiAdr(a4),a2
  1127. MuSt0    move.w    (a2)+,d0
  1128.     bpl.s    DoNote
  1129.     move.w    d0,d1
  1130.     and.w    #$7F00,d0
  1131.     lsr.w    #6,d0
  1132.     jmp    0(a1,d0.w)
  1133.  
  1134. ******* Play a note
  1135. DoNote    btst    #14,d0
  1136.     bne.s    OldNote
  1137. * Play normal note
  1138.     and.w    #$0FFF,d0
  1139.     move.l    BankInst-MB(a3),d1
  1140.     move.l    VoiInst(a4),a0
  1141.     add.l    (a0),d1
  1142.     move.l    d1,(a6)
  1143.     move.w    8(a0),$04(a6)
  1144.     bset    d6,d7
  1145.     bclr    d6,MuStop+1(a5)
  1146.     bset    d6,MuStart+1(a5)
  1147.     move.b    VoiVol+1(a4),0(a3,d6.w)
  1148.     tst.b    VoiPTone(a4)
  1149.     bne.s    MuSt1
  1150. * No portamento
  1151.     move.w    d0,VoiNote(a4)
  1152.     move.w    d0,$06(a6)
  1153.     bra.s    MuSt0
  1154. * Start portamento
  1155. MuSt1    clr.b    VoiPTone(a4)
  1156.     move.w    d0,VoiPToTo(a4)
  1157.     lea    MuPTone(pc),a0
  1158.     move.l    a0,VoiEffect(a4)
  1159.     bra.s    MuSt0
  1160. * Play note compatible with first version
  1161. OldNote    move.w    d0,VoiCpt(a4)
  1162.     move.w    (a2)+,d0
  1163.     beq.s    ONoteE
  1164.     and.w    #$0FFF,d0
  1165.     move.w    d0,VoiNote(a4)
  1166.     move.w    d0,$06(a6)
  1167.     move.l    BankInst-MB(a3),d0
  1168.     move.l    VoiInst(a4),a0
  1169.     add.l    (a0),d0
  1170.     move.l    d0,(a6)
  1171.     move.w    8(a0),$04(a6)
  1172.     bset    d6,d7
  1173.     bclr    d6,MuStop+1(a5)
  1174.     bset    d6,MuStart+1(a5)
  1175.     move.b    VoiVol+1(a4),0(a3,d6.w)
  1176. ONoteE    move.l    a2,VoiAdr(a4)
  1177.     rts
  1178.  
  1179. ******* Jump table to labels
  1180. MuJumps    bra    EtEnd            * 00-> Fin pattern
  1181.     bra    MuSt0            * 01-> Old Slide up
  1182.     bra    MuSt0            * 02-> Old Slide down
  1183.     bra    EtSVol            * 03-> Set volume
  1184.     bra    EtStop            * 04-> Stop effet
  1185.     bra    EtRep            * 05-> Repeat
  1186.     bra    EtLOn            * 06-> Led On
  1187.     bra    EtLOff            * 07-> Led Off
  1188.     bra    EtTemp            * 08-> Set Tempo
  1189.     bra    EtInst            * 09-> Set Instrument
  1190.     bra    EtArp            * 10-> Arpeggiato
  1191.     bra    EtPort            * 11-> Portamento
  1192.     bra    EtVib            * 12-> Vibrato
  1193.     bra    EtVSl            * 13-> Volume slide
  1194.     bra    EtSlU            * 14-> Slide up
  1195.     bra    EtSlD            * 15-> Slide down
  1196.      bra    EtDel            * 16-> Delay
  1197.     bra    EtJmp            * 17-> Position jump
  1198.     bra    MuSt0            * 18-> Free space
  1199.     bra    MuSt0            * 19-> Free space
  1200.     bra    MuSt0            * 20-> Free space
  1201.     bra    MuSt0            * 21-> Free space
  1202.     bra    MuSt0            * 22-> Free space
  1203.     bra    MuSt0            * 23-> Free space
  1204.     bra    MuSt0            * 24-> Free space
  1205.     bra    MuSt0            * 25-> Free space
  1206.     bra    MuSt0            * 26-> Free space
  1207.     bra    MuSt0            * 27-> Free space
  1208.     bra    MuSt0            * 28-> Free space
  1209.     bra    MuSt0            * 29-> Free space
  1210.     bra    MuSt0            * 30-> Free space
  1211.     bra    MuSt0            * 31-> Free space
  1212.  
  1213. ******* End of a pattern
  1214. EtEnd    clr.w    VoiCpt(a4)
  1215.     clr.w    VoiRep(a4)
  1216.     clr.l    VoiDeb(a4)
  1217.     lea    NoEffect(pc),a0
  1218.     move.l    a0,VoiEffect(a4)
  1219.     move.l    VoiPat(a4),a0
  1220. RePat    moveq    #0,d0
  1221.     move.w    (a0)+,d0
  1222.     bmi.s    EtEnd1
  1223.     move.l    a0,VoiPat(a4)
  1224.     move.l    BankPat-MB(a3),a0
  1225.     cmp.w    (a0),d0
  1226.     bhi.s    EtEndX
  1227.     lsl.w    #2,d0
  1228.     add.w    d6,d0
  1229.     lsl.w    #1,d0
  1230.     move.w    2(a0,d0.w),d0
  1231.     beq.s    EtEndX
  1232.     lea    0(a0,d0.l),a2
  1233.     bra    MuSt0
  1234. EtEndX    rts
  1235. EtEnd1    cmp.w    #-1,d0
  1236.     beq.s    EtEndX
  1237.      move.l    VoiDPat(a4),a0
  1238.     bra.s    RePat
  1239. ******* Change instrument
  1240. EtInst    and.w    #$00FF,d1
  1241.     move.l    BankInst-MB(a3),a0
  1242.     lsl.w    #5,d1
  1243.     lea    2(a0,d1.w),a0
  1244.     move.l    a0,VoiInst(a4)
  1245.     move.w    12(a0),d0
  1246.     cmp.w    #64,d0
  1247.     bcs.s    EtInst1
  1248.     moveq    #63,d0
  1249. EtInst1    move.w    d0,VoiDVol(a4)
  1250.     mulu    MuVolume-MB(a3),d0
  1251.     lsr.w    #6,d0
  1252.     move.w    d0,VoiVol(a4)
  1253.     bra    MuSt0
  1254. ******* Set Volume
  1255. EtSVol    and.w    #$00FF,d1
  1256.     cmp.w    #64,d1
  1257.     bcs.s    EtSVol1
  1258.     moveq    #63,d1
  1259. EtSVol1    move.w    d1,VoiDVol(a4)
  1260.     mulu    MuVolume-MB(a3),d1
  1261.     lsr.w    #6,d1
  1262.     move.w    d1,VoiVol(a4)
  1263.     bra    MuSt0
  1264. ******* Set Tempo
  1265. EtTemp    and.w    #$00FF,d1
  1266.     move.w    d1,MuTempo(a5)
  1267.     bra    MuSt0
  1268. ******* Led On
  1269. EtLOn    bclr    #1,$bfe001
  1270.     bra    MuSt0
  1271. ******* Led Off
  1272. EtLOff    bset    #1,$bfe001
  1273.     bra    MuSt0
  1274. ******* Repeat
  1275. EtRep    and.w    #$00FF,d1
  1276.     bne.s    EtRep1
  1277.     move.l    a2,VoiDeb(a4)
  1278.     bra    MuSt0
  1279. EtRep1    tst.w    VoiRep(a4)
  1280.     bne.s    EtRep2
  1281.     move.w    d1,VoiRep(a4)
  1282.     bra    MuSt0
  1283. EtRep2    subq.w    #1,VoiRep(a4)
  1284.     beq    MuSt0
  1285.     move.l    VoiDeb(a4),d0
  1286.     beq    MuSt0
  1287.     move.l    d0,a2
  1288.     bra    MuSt0
  1289. ******* Arpeggio
  1290. EtArp    move.b    d1,VoiValue+1(a4)
  1291.     lea    MuArp(pc),a0
  1292.     move.l    a0,VoiEffect(a4)
  1293.     bra    MuSt0
  1294. ******* Portamento
  1295. EtPort    move.b    #1,VoiPTone(a4)
  1296.     lea    MuPTone(pc),a0
  1297.     bra.s    EtSetE
  1298. ******* Vibrato
  1299. EtVib    lea    MuVib(pc),a0
  1300.     bra.s    EtSetE
  1301. ******* Volume slide
  1302. EtVSl    and.w    #$00FF,d1
  1303.     move.w    d1,d0
  1304.     lsr.w    #4,d0
  1305.     tst.w    d0
  1306.     bne.s    VsEnd
  1307.     and.w    #$000F,d1
  1308.     neg.w    d1
  1309.     move.w    d1,d0
  1310. VsEnd    move.w    d0,VoiValue(a4)
  1311.     lea    MuVSl(pc),a0
  1312.     move.l    a0,VoiEffect(a4)
  1313.     bra    MuSt0
  1314. ******* Slide up
  1315. EtSlU    and.w    #$00FF,d1
  1316.     neg.w    d1
  1317.     lea    MuSlide(pc),a0
  1318.     bra.s    EtSte
  1319. ******* Slide Down
  1320. EtSlD    lea    MuSlide(pc),a0
  1321. EtSetE    and.w    #$00FF,d1
  1322. EtSte    move.w    d1,VoiValue(a4)
  1323.     move.l    a0,VoiEffect(a4)
  1324.     bra    MuSt0
  1325. ******* Stop effect
  1326. EtStop    lea    NoEffect(pc),a0
  1327.     move.l    a0,VoiEffect(a4)
  1328.     bra    MuSt0
  1329. ******* Jump to pattern
  1330. EtJmp    and.w    #$00FF,d1
  1331.     lsl.w    #1,d1
  1332.     move.l    VoiDPat(a4),a0
  1333.     add.w    d1,a0
  1334.     move.l    a0,VoiPat(a4)
  1335.     bra    EtEnd
  1336. ******* Delay
  1337. EtDel    move.w    d1,VoiCpt(a4)
  1338.     move.l    a2,VoiAdr(a4)
  1339.     rts
  1340.  
  1341. ******* Effect routines
  1342.  
  1343. * Performs all effects
  1344. DoEffects
  1345.     move.l    a5,a4
  1346.     move.l    MuChip0-MB(a3),a6
  1347.     move.l    VoiEffect(a4),a0
  1348.     jsr    (a0)
  1349.     move.w    VoiVol(a4),$08(a6)
  1350.     lea    MuVoix1(a5),a4
  1351.     move.l    MuChip1-MB(a3),a6
  1352.     move.l    VoiEffect(a4),a0
  1353.     jsr    (a0)
  1354.     move.w    VoiVol(a4),$08(a6)
  1355.     lea    MuVoix2(a5),a4
  1356.     move.l    MuChip2-MB(a3),a6
  1357.     move.l    VoiEffect(a4),a0
  1358.     jsr    (a0)
  1359.     move.w    VoiVol(a4),$08(a6)
  1360.     lea    MuVoix3(a5),a4
  1361.     move.l    MuChip3-MB(a3),a6
  1362.     move.l    VoiEffect(a4),a0
  1363.     jsr    (a0)
  1364.     move.w    VoiVol(a4),$08(a6)
  1365.     rts
  1366.  
  1367. * TONE SLIDE
  1368. MuSlide    move.w    VoiValue(a4),d0
  1369.     beq.s    NoMoreE
  1370.     add.w    VoiNote(a4),d0
  1371.     cmp.w    #$71,d0
  1372.     bcc.s    MuSl1
  1373.     moveq    #$71,d0
  1374.     bsr    NoMoreE
  1375. MuSl1    cmp.w    #$358,d0
  1376.     bls.s    MuSl2
  1377.     move.w    #$358,d0
  1378.     bsr    NoMoreE
  1379. MuSl2    move.w    d0,VoiNote(a4)
  1380.     move.w    d0,$06(a6)
  1381.     rts
  1382. NoMoreE    lea    NoEffect(pc),a0
  1383.     move.l    a0,VoiEffect(a4)
  1384.     rts
  1385. NoEffect
  1386.     move.w    VoiNote(a4),$06(a6)
  1387.     rts
  1388.  
  1389. * ARPEGGIO
  1390. MuArp    moveq    #0,d0
  1391.     move.b    VoiValue+1(a4),d0
  1392.     move.b    VoiValue(a4),d1
  1393.     cmp.b    #3,d1
  1394.     bcs.s    MuArp0
  1395.     moveq    #2,d1
  1396. MuArp0    subq.b    #1,d1
  1397.     move.b    d1,VoiValue(a4)
  1398.     beq.s    MuArp2
  1399.     bpl.s    MuArp1
  1400.     lsr.b    #4,d0
  1401.     bra.s    MuArp3
  1402. MuArp1    and.b    #$0f,d0
  1403.     bra.s    MuArp3
  1404. MuArp2    move.w    VoiNote(a4),d2
  1405.     bra.s    MuArp4
  1406. MuArp3    add.w    d0,d0
  1407.     moveq    #0,d1
  1408.     move.w    VoiNote(a4),d1
  1409.     lea    Periods(pc),a0
  1410.     moveq    #$24,d3
  1411. MuArpL    move.w    (a0,d0.w),d2
  1412.     cmp.w    (a0),d1
  1413.     bge.s    MuArp4
  1414.     addq.l    #2,a0
  1415.     dbra    d3,MuArpL
  1416.     rts
  1417. MuArp4    move.w    d2,$06(a6)
  1418.     rts
  1419.  
  1420. * PORTAMENTO
  1421. MuPTone    move.w    VoiValue(a4),d0
  1422.     move.w    VoiNote(a4),d1
  1423.     cmp.w    VoiPToTo(a4),d1
  1424.     beq.s    MuPTo3
  1425.     bcs.s    MuPTo1
  1426.     sub.w    d0,d1
  1427.     cmp.w    VoiPToTo(a4),d1
  1428.     bhi.s    MuPto4
  1429.     bra.s    MuPTo2
  1430. MuPTo1    add.w    d0,d1
  1431.     cmp.w    VoiPToTo(a4),d1
  1432.     bcs.s    MuPTo4
  1433. MuPTo2    move.w    VoiPToTo(a4),d1
  1434. MuPTo3    bsr    NoMoreE
  1435. MuPTo4    move.w    d1,VoiNote(a4)
  1436.     move.w    d1,$06(a6)
  1437.     rts
  1438.  
  1439. * VIBRATO
  1440. MuVib    move.b    VoiVib(a4),d0
  1441.     lea    Sinus(pc),a0
  1442.     lsr.w    #2,d0
  1443.     and.w    #$1f,d0
  1444.     moveq    #0,d2
  1445.     move.b    0(a0,d0.w),d2
  1446.     move.b    VoiValue+1(a4),d0
  1447.     and.w    #$0F,d0
  1448.     mulu    d0,d2
  1449.     lsr.w    #$06,d2
  1450.     move.w    VoiNote(a4),d0
  1451.     tst.b    VoiVib(a4)
  1452.     bmi.s    MuVib1
  1453.     add.w    d2,d0
  1454.     bra.s    MuVib2
  1455. MuVib1    sub.w    d2,d0
  1456. MuVib2    move.w    d0,$06(a6)
  1457.     move.b    VoiValue+1(a4),d0
  1458.     lsr.w    #2,d0
  1459.     and.w    #$3C,d0
  1460.     add.b    d0,VoiVib(a4)
  1461.     rts
  1462.  
  1463. * VOLUME SLIDE
  1464. MuVSl    move.w    VoiDVol(a4),d0
  1465.     add.w    VoiValue(a4),d0
  1466.     bpl.s    MuVSl1
  1467.     clr.w    d0
  1468. MuVSl1    cmp.w    #$40,d0
  1469.     bcs.s    MuVSl2
  1470.     moveq    #$3F,d0
  1471. MuVSl2    move.w    d0,VoiDVol(a4)
  1472.     mulu    MuVolume-MB(a3),d0
  1473.     lsr.w    #6,d0
  1474.     move.w    d0,VoiVol(a4)
  1475.     rts
  1476.  
  1477. *******    Routine called every VBL
  1478. MuEvery    
  1479.  
  1480. * Second step of sample?
  1481.     move.w    MuStop(a5),d0
  1482.     beq    MuEvX
  1483.     move.l    BankInst-MB(a3),d1
  1484.     btst    #0,d0                * Voix 0
  1485.     beq.s    MuEv0
  1486.     move.l    MuChip0-MB(a3),a6
  1487.     move.l    VoiInst0(a5),a0
  1488.     move.l    d1,d2
  1489.     add.l    4(a0),d2
  1490.     move.l    d2,(a6)
  1491.     move.w    10(a0),$04(a6)
  1492. MuEv0    btst    #1,d0                * Voix 1
  1493.     beq.s    MuEv1
  1494.     move.l    MuChip1-MB(a3),a6
  1495.     move.l    VoiInst1(a5),a0
  1496.     move.l    d1,d2
  1497.     add.l    4(a0),d2
  1498.     move.l    d2,(a6)
  1499.     move.w    10(a0),$04(a6)
  1500. MuEv1    btst    #2,d0                * Voix 2
  1501.     beq.s    MuEv2
  1502.     move.l    MuChip2-MB(a3),a6
  1503.     move.l    VoiInst2(a5),a0
  1504.     move.l    d1,d2
  1505.     add.l    4(a0),d2
  1506.     move.l    d2,(a6)
  1507.     move.w    10(a0),$04(a6)
  1508. MuEv2    btst    #3,d0                * Voix 3
  1509.     beq.s    MuEv3
  1510.     move.l    MuChip3-MB(a3),a6
  1511.     move.l    VoiInst3(a5),a0
  1512.     move.l    d1,d2
  1513.     add.l    4(a0),d2
  1514.     move.l    d2,(a6)
  1515.     move.w    10(a0),$04(a6)
  1516. MuEv3    
  1517.  
  1518. * Start a voice
  1519. MuEvX    move.w    MuStart(a5),d1
  1520.     move.w    d1,MuStop(a5)
  1521.     clr.w    MuStart(a5)
  1522.     or.w    d1,d0
  1523.     and.w    MuDMAsk-MB(a3),d0
  1524.     bset    #15,d0
  1525.     move.w    d0,$DFF096
  1526.  
  1527. * Restart voices?
  1528.     move.w    MuReStart-MB(a3),d0
  1529.     beq    MuRsX
  1530.     moveq    #0,d3
  1531.     btst    #0,d0                * Voix 0
  1532.     beq.s    MuRs0
  1533.     lea    $DFF0A0,a6
  1534.     move.l    a6,MuChip0-MB(a3)
  1535.     move.w    #2,$04(a6)
  1536.     tst.l    VoiInst0(a5)
  1537.     beq.s    MuRs0
  1538.     bset    #0,d3
  1539. MuRs0    btst    #1,d0                * Voix 1
  1540.     beq.s    MuRs1
  1541.     lea    $DFF0B0,a6
  1542.     move.l    a6,MuChip1-MB(a3)
  1543.     move.w    #2,$04(a6)
  1544.     tst.l    VoiInst1(a5)
  1545.     beq.s    MuRs1
  1546.     bset    #1,d3
  1547. MuRs1    btst    #2,d0                * Voix 2
  1548.     beq.s    MuRs2
  1549.     lea    $DFF0C0,a6
  1550.     move.l    a6,MuChip2-MB(a3)
  1551.     move.w    #2,$04(a6)
  1552.     tst.l    VoiInst2(a5)
  1553.     beq.s    MuRs2
  1554.     bset    #2,d3
  1555. MuRs2    btst    #3,d0                * Voix 3
  1556.     beq.s    MuRs3
  1557.     lea    $DFF0D0,a6
  1558.     move.l    a6,MuChip3-MB(a3)
  1559.     move.w    #2,$04(a6)
  1560.     tst.l    VoiInst3(a5)
  1561.     beq.s    MuRs3
  1562.     bset    #3,d3
  1563. MuRs3    clr.w    MuReStart-MB(a3)
  1564.     or.w    d0,MuDMAsk-MB(a3)
  1565.     or.w    d3,MuStop(a5)
  1566. MuRsX    
  1567.     rts
  1568.  
  1569.  
  1570. ***********************************************************
  1571. *
  1572. *    TRACKER INTERRUPT ROUTINES
  1573. *
  1574. ***********************************************************    
  1575. Tracker    move.b    mt_on(pc),d0
  1576.     beq.s    .Skip
  1577.     movem.l    a4-a6,-(sp)
  1578. ; Poke les deuxiemes parties des samples
  1579. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  1580.     tst.w    mt_dmacon-MB(a3)
  1581.     beq.s    .SkipD
  1582.     lea    mt_voice1(pc),a1
  1583.     lea    $dff000,a0
  1584.     move.l    $a(a1),$a0(a0)
  1585.     move.w    $e(a1),$a4(a0)
  1586.     move.l    $a+$1c(a1),$b0(a0)
  1587.     move.w    $e+$1c(a1),$b4(a0)
  1588.     move.l    $a+$38(a1),$c0(a0)
  1589.     move.w    $e+$38(a1),$c4(a0)
  1590.     move.l    $a+$54(a1),$d0(a0)
  1591.     move.w    $e+$54(a1),$d4(a0)
  1592. ; Appelle la musique
  1593. ; ~~~~~~~~~~~~~~~~~~
  1594. .SkipD    bsr    mt_music
  1595.     movem.l    (sp)+,a4-a6
  1596. .Skip    rts
  1597.  
  1598. mt_music:
  1599.     move.l    mt_data(pc),a0
  1600.     lea    mt_voice1(pc),a4
  1601.     addq.b    #1,mt_counter-mt_voice1(a4)
  1602.     move.b    mt_counter(pc),d0
  1603.     cmp.b    mt_speed(pc),d0
  1604.     blt    mt_nonew
  1605.     moveq    #0,d0
  1606.     move.b    d0,mt_counter-mt_voice1(a4)
  1607.     move.w    d0,mt_dmacon-mt_voice1(a4)
  1608.     move.l    mt_data(pc),a0
  1609.     lea    $3b8(a0),a2
  1610.     lea    $43c(a0),a0
  1611.  
  1612.     moveq    #0,d1
  1613.     move.b    mt_songpos(pc),d0
  1614.     move.b    (a2,d0.w),d1
  1615.     lsl.w    #8,d1
  1616.     lsl.w    #2,d1
  1617.     add.w    mt_pattpos(pc),d1
  1618.  
  1619.     lea    $dff0a0,a5
  1620.     lea    mt_samplestarts-4(pc),a1
  1621.     lea    mt_playvoice(pc),a6
  1622.     jsr    (a6)
  1623.     addq.l    #4,d1
  1624.     lea    $dff0b0,a5
  1625.     lea    mt_voice2(pc),a4
  1626.     jsr    (a6)
  1627.     addq.l    #4,d1
  1628.     lea    $dff0c0,a5
  1629.     lea    mt_voice3(pc),a4
  1630.     jsr    (a6)
  1631.     addq.l    #4,d1
  1632.     lea    $dff0d0,a5
  1633.     lea    mt_voice4(pc),a4
  1634.     jsr    (a6)
  1635.  
  1636.     move.w    mt_dmacon(pc),d0
  1637.     beq.s    mt_nodma
  1638.     or.w    #$8000,mt_dmacon-mt_voice4(a4)
  1639.  
  1640. mt_nodma:
  1641.     add.w    #$10,mt_pattpos-mt_voice4(a4)
  1642.     cmp.w    #$400,mt_pattpos-mt_voice4(a4)
  1643.     bne.s    mt_exit
  1644. mt_next:clr.w    mt_pattpos-mt_voice4(a4)
  1645.     clr.b    mt_break-mt_voice4(a4)
  1646.     addq.b    #1,mt_songpos-mt_voice4(a4)
  1647.     and.b    #$7f,mt_songpos-mt_voice4(a4)
  1648.     move.b    -2(a2),d0
  1649.     cmp.b    mt_songpos(pc),d0
  1650.     bne.s    mt_exit
  1651.     move.b    -1(a2),mt_songpos-mt_voice4(a4)
  1652. mt_exit:tst.b    mt_break-mt_voice4(a4)
  1653.     bne.s    mt_next
  1654. ; Provoque l'actualisation du DMA
  1655.     move.w    mt_dmacon(pc),d0
  1656.     beq.s    .Skip
  1657.     moveq    #4,d3        
  1658. .wai2    move.b    $dff006,d2    
  1659. .wai3    cmp.b    $dff006,d2    
  1660.     beq.s    .wai3
  1661.     dbf    d3,.wai2    
  1662.     move.w    d0,$dff096
  1663. .Skip    rts
  1664.  
  1665. mt_nonew:
  1666.     lea    $dff0a0,a5
  1667.     lea    mt_com(pc),a6
  1668.     jsr    (a6)
  1669.     lea    mt_voice2(pc),a4
  1670.     lea    $dff0b0,a5
  1671.     jsr    (a6)
  1672.     lea    mt_voice3(pc),a4
  1673.     lea    $dff0c0,a5
  1674.     jsr    (a6)
  1675.     lea    mt_voice4(pc),a4
  1676.     lea    $dff0d0,a5
  1677.     jsr    (a6)
  1678.     tst.b    mt_break-mt_voice4(a4)
  1679.     bne    mt_next
  1680.     rts
  1681.  
  1682. mt_playvoice:
  1683.     move.l    (a0,d1.l),(a4)
  1684.     moveq    #0,d2
  1685.     move.b    2(a4),d2
  1686.     lsr.b    #4,d2
  1687.     move.b    (a4),d0
  1688.     and.b    #$f0,d0
  1689.     or.b    d0,d2
  1690.     beq    mt_oldinstr
  1691.  
  1692.     asl.w    #2,d2
  1693.     move.l    (a1,d2.l),4(a4)
  1694.     move.l    mt_mulu(pc,d2.w),a3
  1695.     move.w    (a3)+,8(a4)
  1696.     move.w    (a3)+,$12(a4)
  1697.     move.l    4(a4),d0
  1698.     moveq    #0,d3
  1699.     move.w    (a3)+,d3
  1700.     beq    mt_noloop
  1701.     asl.w    #1,d3
  1702.     add.l    d3,d0
  1703.     move.l    d0,$a(a4)
  1704.     move.w    -2(a3),d0
  1705.     add.w    (a3),d0
  1706.     move.w    d0,8(a4)
  1707.     bra    mt_hejaSverige
  1708.  
  1709. mt_mulu:dcb.l    $20,0
  1710.  
  1711. mt_noloop:
  1712.     add.l    d3,d0
  1713.     move.l    d0,$a(a4)
  1714. mt_hejaSverige:
  1715.     move.w    (a3),$e(a4)
  1716.     move.w    $12(a4),8(a5)
  1717.  
  1718. mt_oldinstr:
  1719.     move.w    (a4),d3
  1720.     and.w    #$fff,d3
  1721.     beq    mt_com2
  1722.     tst.w    8(a4)
  1723.     beq.s    mt_stopsound
  1724.     move.b    2(a4),d0
  1725.     and.b    #$f,d0
  1726.     cmp.b    #5,d0
  1727.     beq.s    mt_setport
  1728.     cmp.b    #3,d0
  1729.     beq.s    mt_setport
  1730.  
  1731.     move.w    d3,$10(a4)
  1732.     move.w    $1a(a4),$dff096
  1733.     clr.b    $19(a4)
  1734.  
  1735.     move.l    4(a4),(a5)
  1736.     move.w    8(a4),4(a5)
  1737.     move.w    $10(a4),6(a5)
  1738.  
  1739.     move.w    $1a(a4),d0
  1740.     or.w    d0,mt_dmacon-mt_playvoice(a6)
  1741.     bra    mt_com2
  1742.  
  1743. mt_stopsound:
  1744.     move.w    $1a(a4),$dff096
  1745.     bra    mt_com2
  1746.  
  1747. mt_setport:
  1748.     move.w    (a4),d2
  1749.     and.w    #$fff,d2
  1750.     move.w    d2,$16(a4)
  1751.     move.w    $10(a4),d0
  1752.     clr.b    $14(a4)
  1753.     cmp.w    d0,d2
  1754.     beq.s    mt_clrport
  1755.     bge    mt_com2
  1756.     move.b    #1,$14(a4)
  1757.     bra    mt_com2
  1758. mt_clrport:
  1759.     clr.w    $16(a4)
  1760.     rts
  1761.  
  1762. mt_port:moveq    #0,d0
  1763.     move.b    3(a4),d2
  1764.     beq.s    mt_port2
  1765.     move.b    d2,$15(a4)
  1766.     move.b    d0,3(a4)
  1767. mt_port2:
  1768.     tst.w    $16(a4)
  1769.     beq.s    mt_rts
  1770.     move.b    $15(a4),d0
  1771.     tst.b    $14(a4)
  1772.     bne.s    mt_sub
  1773.     add.w    d0,$10(a4)
  1774.     move.w    $16(a4),d0
  1775.     cmp.w    $10(a4),d0
  1776.     bgt.s    mt_portok
  1777.     move.w    $16(a4),$10(a4)
  1778.     clr.w    $16(a4)
  1779. mt_portok:
  1780.     move.w    $10(a4),6(a5)
  1781. mt_rts:    rts
  1782.  
  1783. mt_sub:    sub.w    d0,$10(a4)
  1784.     move.w    $16(a4),d0
  1785.     cmp.w    $10(a4),d0
  1786.     blt.s    mt_portok
  1787.     move.w    $16(a4),$10(a4)
  1788.     clr.w    $16(a4)
  1789.     move.w    $10(a4),6(a5)
  1790.     rts
  1791.  
  1792. mt_sin:
  1793.     dc.b $00,$18,$31,$4a,$61,$78,$8d,$a1,$b4,$c5,$d4,$e0,$eb,$f4,$fa,$fd
  1794.     dc.b $ff,$fd,$fa,$f4,$eb,$e0,$d4,$c5,$b4,$a1,$8d,$78,$61,$4a,$31,$18
  1795.  
  1796. mt_vib:    move.b    $3(a4),d0
  1797.     beq.s    mt_vib2
  1798.     move.b    d0,$18(a4)
  1799.  
  1800. mt_vib2:move.b    $19(a4),d0
  1801.     lsr.w    #2,d0
  1802.     and.w    #$1f,d0
  1803.     moveq    #0,d2
  1804.     move.b    mt_sin(pc,d0.w),d2
  1805.     move.b    $18(a4),d0
  1806.     and.w    #$f,d0
  1807.     mulu    d0,d2
  1808.     lsr.w    #7,d2
  1809.     move.w    $10(a4),d0
  1810.     tst.b    $19(a4)
  1811.     bmi.s    mt_vibsub
  1812.     add.w    d2,d0
  1813.     bra.s    mt_vib3
  1814. mt_vibsub:
  1815.     sub.w    d2,d0
  1816. mt_vib3:move.w    d0,6(a5)
  1817.     move.b    $18(a4),d0
  1818.     lsr.w    #2,d0
  1819.     and.w    #$3c,d0
  1820.     add.b    d0,$19(a4)
  1821.     rts
  1822.  
  1823. mt_arplist:
  1824.     dc.b 0,1,2,0,1,2,0,1,2,0,1,2,0,1,2,0,1,2,0,1,2,0,1,2,0,1,2,0,1,2,0,1
  1825.  
  1826. mt_arp:    moveq    #0,d0
  1827.     move.b    mt_counter(pc),d0
  1828.     move.b    mt_arplist(pc,d0.w),d0
  1829.     beq.s    mt_normper
  1830.     cmp.b    #2,d0
  1831.     beq.s    mt_arp2
  1832. mt_arp1:move.b    3(a4),d0
  1833.     lsr.w    #4,d0
  1834.     bra.s    mt_arpdo
  1835. mt_arp2:move.b    3(a4),d0
  1836.     and.w    #$f,d0
  1837. mt_arpdo:
  1838.     asl.w    #1,d0
  1839.     move.w    $10(a4),d1
  1840.     lea    mt_periods(pc),a0
  1841. mt_arp3:cmp.w    (a0)+,d1
  1842.     blt.s    mt_arp3
  1843.     move.w    -2(a0,d0.w),6(a5)
  1844.     rts
  1845.  
  1846. mt_normper:
  1847.     move.w    $10(a4),6(a5)
  1848.     rts
  1849.  
  1850. mt_com:    move.w    2(a4),d0
  1851.     and.w    #$fff,d0
  1852.     beq.s    mt_normper
  1853.     move.b    2(a4),d0
  1854.     and.b    #$f,d0
  1855.     beq.s    mt_arp
  1856.     cmp.b    #6,d0
  1857.     beq.s    mt_volvib
  1858.     cmp.b    #4,d0
  1859.     beq    mt_vib
  1860.     cmp.b    #5,d0
  1861.     beq.s    mt_volport
  1862.     cmp.b    #3,d0
  1863.     beq    mt_port
  1864.     cmp.b    #1,d0
  1865.     beq.s    mt_portup
  1866.     cmp.b    #2,d0
  1867.     beq.s    mt_portdown
  1868.     move.w    $10(a4),6(a5)
  1869.     cmp.b    #$a,d0
  1870.     beq.s    mt_volslide
  1871.     rts
  1872.  
  1873. mt_portup:
  1874.     moveq    #0,d0
  1875.     move.b    3(a4),d0
  1876.     sub.w    d0,$10(a4)
  1877.     move.w    $10(a4),d0
  1878.     cmp.w    #$71,d0
  1879.     bpl.s    mt_portup2
  1880.     move.w    #$71,$10(a4)
  1881. mt_portup2:
  1882.     move.w    $10(a4),6(a5)
  1883.     rts
  1884.  
  1885. mt_portdown:
  1886.     moveq    #0,d0
  1887.     move.b    3(a4),d0
  1888.     add.w    d0,$10(a4)
  1889.     move.w    $10(a4),d0
  1890.     cmp.w    #$358,d0
  1891.     bmi.s    mt_portdown2
  1892.     move.w    #$358,$10(a4)
  1893. mt_portdown2:
  1894.     move.w    $10(a4),6(a5)
  1895.     rts
  1896.  
  1897. mt_volvib:
  1898.      bsr    mt_vib2
  1899.      bra.s    mt_volslide
  1900. mt_volport:
  1901.      bsr    mt_port2
  1902.  
  1903. mt_volslide:
  1904.     moveq    #0,d0
  1905.     move.b    3(a4),d0
  1906.     lsr.b    #4,d0
  1907.     beq.s    mt_vol3
  1908.     add.b    d0,$13(a4)
  1909.     cmp.b    #$40,$13(a4)
  1910.     bmi.s    mt_vol2
  1911.     move.b    #$40,$13(a4)
  1912. mt_vol2:move.w    $12(a4),8(a5)
  1913.     rts
  1914.  
  1915. mt_vol3:move.b    3(a4),d0
  1916.     and.b    #$f,d0
  1917.     sub.b    d0,$13(a4)
  1918.     bpl.s    mt_vol4
  1919.     clr.b    $13(a4)
  1920. mt_vol4:move.w    $12(a4),8(a5)
  1921.     rts
  1922.  
  1923. mt_com2:move.b    2(a4),d0
  1924.     and.b    #$f,d0
  1925.     beq    mt_rts
  1926.     cmp.b    #$e,d0
  1927.     beq.s    mt_filter
  1928.     cmp.b    #$d,d0
  1929.     beq.s    mt_pattbreak
  1930.     cmp.b    #$b,d0
  1931.     beq.s    mt_songjmp
  1932.     cmp.b    #$c,d0
  1933.     beq.s    mt_setvol
  1934.     cmp.b    #$f,d0
  1935.     beq.s    mt_setspeed
  1936.     rts
  1937.  
  1938. mt_filter:
  1939.     move.b    3(a4),d0
  1940.     and.b    #1,d0
  1941.     asl.b    #1,d0
  1942.     and.b    #$fd,$bfe001
  1943.     or.b    d0,$bfe001
  1944.     rts
  1945.  
  1946. mt_pattbreak:
  1947.     move.b    #1,mt_break-mt_playvoice(a6)
  1948.     rts
  1949.  
  1950. mt_songjmp:
  1951.     move.b    #1,mt_break-mt_playvoice(a6)
  1952.     move.b    3(a4),d0
  1953.     subq.b    #1,d0
  1954.     move.b    d0,mt_songpos-mt_playvoice(a6)
  1955.     rts
  1956.  
  1957. mt_setvol:
  1958.     cmp.b    #$40,3(a4)
  1959.     bls.s    mt_sv2
  1960.     move.b    #$40,3(a4)
  1961. mt_sv2:    moveq    #0,d0
  1962.     move.b    3(a4),d0
  1963.     move.b    d0,$13(a4)
  1964.     move.w    d0,8(a5)
  1965.     rts
  1966.  
  1967. mt_setspeed:
  1968.     moveq    #0,d0
  1969.     move.b    3(a4),d0
  1970.     cmp.b    #$1f,d0
  1971.     bls.s    mt_sp2
  1972.     moveq    #$1f,d0
  1973. mt_sp2:    tst.w    d0
  1974.     bne.s    mt_sp3
  1975.     moveq    #1,d0
  1976. mt_sp3:    move.b    d0,mt_speed-mt_playvoice(a6)
  1977.     rts
  1978.  
  1979.  
  1980. *********************************************************************
  1981. *        MUSIC extension data zone
  1982.  
  1983. ; Branches for AMOSPro Editor (-4)
  1984. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  1985.         Rbra    L_GoSam
  1986. MB:
  1987. MuVu        dc.l    0        * Vu Meters
  1988. MuBase        dc.l    0        * Curretn music address
  1989. MusAdr        dc.l    0        * Branch table address
  1990. MusClock    dc.l     3546895        * Clock speed
  1991. WaveBase    dc.l    0        * Wave tree
  1992. Waves        dc.w     0,0,0,0
  1993. EnvOn:        dc.w     0        * ADSR running?
  1994. EnvBase:    ds.b    EnvLong*4    * ADSR table
  1995. SamBank:    dc.w     0        * Sample bank
  1996. BSeed:        dc.w     0        * Random seed
  1997. Noise:        dc.w    0        * Noise on?
  1998. PNoise:        dc.w    0        * Pointer to noise buffer
  1999. TempoBase:    dc.w    0        * 100 (PAL) - 120 (NTSC)
  2000. *         Musique
  2001. MusBank        dc.l     0        * Music bank
  2002. MusCheck    dc.l    0        * Check sum
  2003. BankInst    dc.l    0        * Instruments
  2004. BankSong    dc.l    0        * Songs
  2005. BankPat        dc.l     0        * Patterns
  2006. MuNumber    dc.w    0        * Music priority
  2007. MuVolume    dc.w    0        * Music volume
  2008. MuDMAsk        dc.w    0        * Voice mask
  2009. MuReStart    dc.w    0        * Restart the voice
  2010. MuChip0        dc.l    0        * Circuits 0
  2011. MuChip1        dc.l     0        *       1
  2012. MuChip2        dc.l     0        *          2
  2013. MuChip3        dc.l     0        *          3
  2014. FoEnd        dc.w    $8000        * Fake empty pattern
  2015. MuBuffer    ds.b    MuLong*3    * Music tables
  2016.  
  2017.         RDATA
  2018.  
  2019. *************** Tables for effects
  2020. Sinus    
  2021.  dc.b $00,$18,$31,$4a,$61,$78,$8d,$a1,$b4,$c5,$d4,$e0,$eb,$f4,$fa,$fd
  2022.  dc.b $ff,$fd,$fa,$f4,$eb,$e0,$d4,$c5,$b4,$a1,$8d,$78,$61,$4a,$31,$18
  2023.  
  2024. Periods    
  2025.  dc.w $0358,$0328,$02fa,$02d0,$02a6,$0280,$025c,$023a,$021a,$01fc,$01e0
  2026.  dc.w $01c5,$01ac,$0194,$017d,$0168,$0153,$0140,$012e,$011d,$010d,$00fe
  2027.  dc.w $00f0,$00e2,$00d6,$00ca,$00be,$00b4,$00aa,$00a0,$0097,$008f,$0087
  2028.  dc.w $007f,$0078,$0071,$0000,$0000
  2029.  
  2030. *************** Default enveloppes
  2031. EnvDef:        dc.w 1,64,4,55,5,50,25,0,0,0
  2032. EnvShoot    dc.w 1,64,10,0,0,0
  2033. EnvBoom        dc.w 1,64,10,50,50,0,0,0
  2034. EnvBell        dc.w 1,64,4,40,25,0,0,0
  2035.  
  2036. *************** Bank headers
  2037. BkMus:        dc.b "Music   "
  2038.  
  2039. *************** Frequency / notes
  2040. TFreq:    dc.w 000,256/2
  2041.     dc.w 000,256/2
  2042.     dc.w 256,128/2
  2043.     dc.w 384,64/2
  2044.     dc.w 448,32/2
  2045.     dc.w 480,16/2
  2046.     dc.w 496,8/2
  2047.     dc.w 504,4/2
  2048.     dc.w 504,4/2
  2049. TNotes:    dc.w 00,00,00,33,35,37,39,41,44,46,49,52
  2050.     dc.w 55,58,62,65,69,73,78,82,87,92,98,104
  2051.     dc.w 110,117,123,131,139,147,156,165,175,185,196,208
  2052.     dc.w 220,233,247,262,277,294,311,330,349,370,392,415
  2053.     dc.w 440,466,494,523,554,587,622,659,698,740,784,830
  2054.     dc.w 880,932,988,1046,1109,1175,1245,1319,1397,1480,1568,1661
  2055.     dc.w 1760,1865,1986,2093,2217,2349,2489,2637,2794,2960,3136,3322
  2056.     dc.w 3520,3729,3952,4186,4435,4699,4978,5274,5588,5920,6272,6645
  2057.     dc.w 7040,7459,7902,8372
  2058.  
  2059. *************** SAMPLE PLAYER INTERRUPT STRUCTURES
  2060. Sami_lplay    equ    1024*4
  2061. Sami_bit    equ    22
  2062. Sami_dma    equ    24
  2063. Sami_reg    equ    26
  2064. Sami_adr    equ    28
  2065. Sami_long    equ    32
  2066. Sami_pos    equ    36
  2067. Sami_rpos    equ    40
  2068. Sami_radr    equ    44
  2069. Sami_rlong    equ    48
  2070. Sami_dvol    equ    52
  2071. Sami_old    equ    54
  2072. Sami_intl    equ    58
  2073.  
  2074. Sami_int    ds.b    22                * Channel 0
  2075.         dc.w    %0000000010000000    bit
  2076.         dc.w    0            dma
  2077.         dc.w    $a0            reg
  2078.         dc.l    0            adr
  2079.         dc.l    0            long
  2080.         dc.l    0            pos
  2081.         dc.l    0            rpos
  2082.         dc.l    0            radr
  2083.         dc.l    0            rlong
  2084.         dc.w    0            dvol
  2085.         dc.l    0            old            
  2086.  
  2087.         ds.b    22                * Channel 1
  2088.         dc.w    %0000000100000000    bit
  2089.         dc.w    1            dma
  2090.         dc.w    $b0            reg
  2091.         dc.l    0            adr
  2092.         dc.l    0            long
  2093.         dc.l    0            pos
  2094.         dc.l    0            rpos
  2095.         dc.l    0            radr
  2096.         dc.l    0            rlong
  2097.         dc.w    0            dvol
  2098.         dc.l    0            old            
  2099.  
  2100.         ds.b    22                * Channel 2
  2101.         dc.w    %0000001000000000    bit
  2102.         dc.w    2            dma
  2103.         dc.w    $c0            reg
  2104.         dc.l    0            adr
  2105.         dc.l    0            long
  2106.         dc.l    0            pos
  2107.         dc.l    0            rpos
  2108.         dc.l    0            radr
  2109.         dc.l    0            rlong
  2110.         dc.w    0            dvol
  2111.         dc.l    0            old            
  2112.  
  2113.         ds.b    22                * Channel 3
  2114.         dc.w    %0000010000000000    bit
  2115.         dc.w    3            dma
  2116.         dc.w    $d0            reg
  2117.         dc.l    0            adr
  2118.         dc.l    0            long
  2119.         dc.l    0            pos
  2120.         dc.l    0            rpos
  2121.         dc.l    0            radr
  2122.         dc.l    0            rlong
  2123.         dc.w    0            dvol
  2124.         dc.l    0            old            
  2125.  
  2126. Sami_OldEna    dc.w    0
  2127. Sami_empty    dc.l    0
  2128. Sami_bits    dc.w    0
  2129. Sami_handad    dc.l    0
  2130. Sami_flag    dc.w    0
  2131. SamLoops    dc.w    0
  2132. *************** NARRATOR
  2133. Amaps:        dc.b    3,5,10,12
  2134. TranBase    dc.l    0
  2135.         even
  2136. L_WriteIo    equ    88
  2137. WriteIo        dc.l    0
  2138. WritePort:    dc.l    0
  2139. L_ReadIo    equ    92
  2140. ReadIo        ds.b    L_ReadIo
  2141. ReadPort    dc.l    0
  2142. TranName    dc.b    "translator.library",0
  2143. NarDevice    dc.b    "narrator.device",0
  2144.         even
  2145.  
  2146. ;     MED data zone
  2147. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  2148. Med_Bank    dc.w    7        Bank number 6= tracker
  2149. Med_Base    dc.l    0
  2150. Med_Adr        dc.l    0
  2151. Med_On        dc.b    0
  2152. Med_Midi    dc.b    0
  2153. Med_Name    dc.b    "medplayer.library",0    
  2154.         even
  2155. _MEDGetPlayer        equ    -30
  2156. _MEDFreePlayer        equ    -36
  2157. _MEDPlayModule        equ    -42
  2158. _MEDContModule        equ    -48
  2159. _MEDStopPlayer        equ    -54
  2160. _MEDDimOffPlayer    equ    -60
  2161. _MEDSetTempo        equ    -66
  2162. _MEDLoadModule        equ    -72
  2163. _MEDUnLoadModule    equ    -78
  2164. _MEDGetCurrentModule    equ    -84
  2165. _MEDResetMIDI        equ    -90
  2166. _MEDSetModnum        equ    -96
  2167. _MEDRelocModule        equ    -102
  2168.  
  2169. *********************************************************************
  2170. *    mt TRACKER data zone
  2171.  
  2172. Track_Bank    dc.w    6        Bank number 6= tracker
  2173. mt_on        dc.b    0
  2174. colour        dc.w    0
  2175.  
  2176. mt_periods:
  2177.     dc.w $0358,$0328,$02fa,$02d0,$02a6,$0280,$025c,$023a,$021a,$01fc,$01e0
  2178.     dc.w $01c5,$01ac,$0194,$017d,$0168,$0153,$0140,$012e,$011d,$010d,$00fe
  2179.     dc.w $00f0,$00e2,$00d6,$00ca,$00be,$00b4,$00aa,$00a0,$0097,$008f,$0087
  2180.     dc.w $007f,$0078,$0071,$0000
  2181.  
  2182. mt_speed:    dc.b    6
  2183. mt_counter:    dc.b    0
  2184. mt_pattpos:    dc.w    0
  2185. mt_songpos:    dc.b    0
  2186. mt_break:    dc.b    0
  2187. mt_dmacon:    dc.w    0
  2188. mt_samplestarts:dcb.l    $1f,0
  2189. mt_voice1:    dcb.w    13,0
  2190.         dc.w    1
  2191. mt_voice2:    dcb.w    13,0
  2192.         dc.w    2
  2193. mt_voice3:    dcb.w    13,0
  2194.         dc.w    4
  2195. mt_voice4:    dcb.w    13,0
  2196.         dc.w    8
  2197. mt_data:    dc.l    0
  2198.         dc.l    0
  2199.  
  2200.  
  2201. **********************************************************************
  2202. ; Please leave 1 or two labels free for future extension. You never
  2203. ; know!
  2204. L1
  2205.  
  2206. ; Now follow all the music routines. Some are just routines called by others,
  2207. ; some are instructions. 
  2208. ; See how a adress the internal music datazone, by using a base register
  2209. ; (usually A3) and adding the offset of the data in the datazone...
  2210.  
  2211. ; >>> How to get the parameters for the instruction?
  2212. ;
  2213. ; When an instruction or function is called, you get the parameters
  2214. ; pushed in A3. Remember that you unpile them in REVERSE order than
  2215. ; the instruction syntax.
  2216. ; As you have a entry point for each set of parameters, you know
  2217. ; how many are pushed...
  2218. ;    - INTEGER:    move.l    (a3)+,d0
  2219. ;    - STRING:    move.l    (a3)+,a0
  2220. ;            move.w    (a0)+,d0
  2221. ;        A0---> start of the string.
  2222. ;        D0---> length of the string
  2223. ;    - FLOAT:    move.l    (a3)+,d0
  2224. ;            fast floatting point format.
  2225. ;
  2226. ; IMPORTANT POINT: you MUST unpile the EXACT number of parameters,
  2227. ; to restore A3 to its original level. If you do not, you will not
  2228. ; have a immediate error, and AMOS will certainely crash on next
  2229. ; UNTIL / WEND / ENDIF / NEXT etc... 
  2230. ;
  2231. ; So, your instruction must:
  2232. ;    - Unpile the EXACT number of parameters from A3, and exit with
  2233. ;    A3 at the original level it was before collecting your parameters)
  2234. ;    - Preserve A4, A5 and A6
  2235. ; You can use D0-D7/A0-A2 freely...
  2236. ;
  2237. ; You can jump to the error routine without thinking about A3 if an error
  2238. ; occurs in your routine (via a RBra of course). BUT A4, A5 and A6 registers
  2239. ; MUST be preserved!
  2240. ;
  2241. ; You end must end by a RTS.
  2242. ;
  2243. ; >>> Functions, how to return the parameter?
  2244. ;
  2245. ; To send a function`s parameter back to AMOS, you load it in D3,
  2246. ; and put its type in D2:
  2247. ;    moveq    #0,d2    for an integer
  2248. ;    moveq    #1,d2    for a float
  2249. ;    moveq    #2,d2    for a string
  2250. ;
  2251.  
  2252. ******* Stop sound routine
  2253. L_MOff        equ    2
  2254. L2    lea    Circuits,a0
  2255.     move.w    #%0000011110000000,IntEna(a0)     * No more interrupts
  2256.     move.w    MuDMAsk-MB(a3),d0
  2257.     beq.s    MOf3
  2258.     move.w    d0,DmaCon(a0)
  2259.     moveq    #3,d1
  2260. MOf1    btst    d1,d0
  2261.     beq.s    MOf2
  2262.     move.w    #2,$a4(a0)
  2263.     clr.w    $a8(a0)
  2264. MOf2    lea    $10(a0),a0
  2265.     dbra    d1,MOf1
  2266. MOf3    rts
  2267.  
  2268. ***********************************************************
  2269. *    NARRATOR!
  2270.  
  2271. ******* Open narrator
  2272. L_OpNar        equ    3
  2273. L3    movem.l    a3-a6,-(sp)
  2274.     Dload    a3
  2275.     move.l    $4.w,a6
  2276.     move.l    TranBase-MB(a3),d0
  2277.     bne    OpNarCheck
  2278.  
  2279. ; Opens communication port
  2280.     clr.l    -(sp)
  2281.     clr.l    -(sp)
  2282.     moveq    #0,d0
  2283.     Rbsr    L_Amiga.Lib
  2284.     addq.l    #8,sp
  2285.     move.l    d0,WritePort-MB(a3)
  2286. ; Opens IO structure
  2287.     move.l    #L_WriteIo,-(sp)
  2288.     move.l    d0,-(sp)
  2289.     moveq    #2,d0
  2290.     Rbsr    L_Amiga.Lib
  2291.     addq.l    #8,sp
  2292.     move.l    d0,WriteIo-Mb(a3)
  2293.     move.l    d0,a1
  2294.     moveq    #0,d0
  2295.     moveq    #0,d1
  2296.     lea    NarDevice-MB(a3),a0
  2297.     jsr    OpenDev(a6)
  2298.     tst.l    d0
  2299.     bne    OpNarE
  2300.  
  2301. ; Open READ structure
  2302.     clr.l    -(sp)
  2303.     clr.l    -(sp)
  2304.     moveq    #0,d0
  2305.     Rbsr    L_Amiga.Lib
  2306.     addq.l    #8,sp
  2307.     move.l    d0,ReadPort-MB(a3)
  2308.     move.l    WriteIo-MB(a3),a0
  2309.     lea    ReadIo-MB(a3),a1
  2310.     moveq    #L_WriteIo/2-1,d0
  2311. .Loop    move.w    (a0)+,(a1)+
  2312.     dbra    d0,.Loop
  2313.     lea    ReadIo-MB(a3),a1
  2314.     move.l    ReadPort-MB(a3),14(a1)
  2315.  
  2316. ; Open translator
  2317.     Rbsr    L_NarInit
  2318.     lea    TranName-MB(a3),a1
  2319.     moveq    #0,d0
  2320.     jsr    OpenLib(a6)
  2321.     move.l    d0,TranBase-MB(a3)
  2322.     beq    OpNarE
  2323. * Restore Sami interrupts
  2324.     move.l    DosBase(a5),a6
  2325.     moveq    #50,d1
  2326.     jsr    -198(a6)
  2327.     clr.w    Sami_Flag-MB(a3)
  2328.     RBsr    L_Sami_Install
  2329. * Ok!
  2330.     movem.l    (sp)+,a3-a6
  2331.     rts
  2332.  
  2333. ;-----> Annule un speech précédent
  2334. OpNarCheck
  2335.     RBsr    L_NarStop
  2336.     movem.l    (sp)+,a3-a6
  2337.     rts
  2338. ;-----> Can't open narrator
  2339. OpNarE    movem.l    (sp)+,a3-a6
  2340. NoNar    moveq    #7,d0
  2341.     Rbra    L_Custom
  2342.  
  2343. ******* Init narrator (if here)!
  2344. L_NarInit    equ    4
  2345. L4    move.l    WriteIO-MB(a3),d0
  2346.     beq.s    .Skip
  2347.     move.l    d0,a1
  2348.     move.w    #150,48(a1)
  2349.     move.w    #110,50(a1)
  2350.     clr.w    52(a1)
  2351.     clr.w    54(a1)
  2352.     lea    Amaps-MB(a3),a0
  2353.     move.l    a0,56(a1)
  2354.     move.w    #4,60(a1)
  2355.     move.w    #63,62(a1)
  2356.     move.w    #22200,64(a1)
  2357. .Skip    rts
  2358.  
  2359. ******* SAY a$[,multi]
  2360. L_ISay2:    equ    5
  2361. L5    Rbsr    L_OpNar
  2362.     move.l    (a3)+,d7
  2363.     RBra    L_ISay
  2364. L_ISay1:    equ    6
  2365. L6    Rbsr    L_OpNar
  2366.     moveq    #0,d7    
  2367.     Rbra    L_ISay
  2368. L_ISay:        equ    7
  2369. L7    moveq    #%0000,d0
  2370.     Rbsr    L_StopDma
  2371.     Rbsr    L_VOnOf
  2372.     DLoad    a0
  2373.     clr.w    EnvOn-MB(a0)
  2374.     clr.w    Noise-MB(a0)
  2375.     move.l    (a3)+,a0
  2376.     moveq    #0,d0
  2377.     move.w    (a0)+,d0
  2378. * Phoneme?
  2379.     cmp.b    #"~",(a0)
  2380.     bne.s    ISayN
  2381.     addq.l    #1,a0
  2382.     move.l    Buffer(a5),a1
  2383.     move.w    d0,d1
  2384.     cmp.w    #1024,d1
  2385.     bcc    ISayN
  2386.     subq.w    #2,d1
  2387.     bmi.s    ISayN
  2388. ISayP    move.b    (a0)+,(a1)+
  2389.     dbra    d1,ISayP
  2390.     move.b    #"Q",(a1)+
  2391.     move.b    #"#",(a1)+
  2392.     move.b    #"U",(a1)+
  2393.     clr.b    (a1)+
  2394.     clr.b    (a1)+
  2395.     addq.w    #4,d0
  2396.     movem.l    a3/a6,-(sp)
  2397.     DLoad    a3
  2398.     bra.s    ISayNn
  2399. * Call TRANSLATOR
  2400. ISayN    move.l    Buffer(a5),a1
  2401.     move.l    a1,a2
  2402.     move.l    #1024,d1
  2403.     move.l    d1,d2
  2404.     lsr.w    #2,d2
  2405.     subq.w    #2,d2
  2406. ISayN1    clr.l    (a2)+
  2407.     dbra    d2,ISayN1
  2408.     movem.l    a3/a6,-(sp)
  2409.     DLoad    a3
  2410.     move.l    TranBase-MB(a3),a6
  2411.     jsr    Translate(a6)
  2412.     tst.w    d0
  2413.     bne.s    SayX
  2414.     move.l    #1024,d0
  2415. ISayNn
  2416.     Rbsr    L_Sami_remove
  2417.     move.l    WriteIO-MB(a3),a1
  2418.     move.w    #3,28(a1)
  2419.     move.l    d0,36(a1)
  2420.     move.l    Buffer(a5),40(a1)
  2421.     move.l    ExecBase,a6
  2422.     tst.w    d7
  2423.     bne.s    ISayA
  2424. ; Mode non multitache
  2425.     clr.b    66(a1)
  2426.     jsr    DoIO(a6)
  2427.     RBsr    L_Sami_install
  2428. SayX    movem.l    (sp)+,a3/a6
  2429.     moveq    #%1111,d0
  2430.     Rbsr    L_VOnOf
  2431.     rts
  2432. ; Mode multitache
  2433. ISayA    move.b    #1,66(a1)        Generer des mouths!
  2434.     jsr    SendIO(a6)
  2435.     movem.l    (sp)+,a3/a6
  2436.     rts
  2437. ******* SET TALK sex,mode,pitch,rate
  2438. L_ITalk        equ    8
  2439. L8    Rbsr    L_OpNar
  2440.     move.l    #EntNul,d0
  2441.     Dload    a1
  2442.     move.l    WriteIo-MB(a1),a1
  2443.     move.l    (a3)+,d1
  2444.     cmp.l    d0,d1
  2445.     beq.s    IRd1
  2446.     cmp.w    #40,d1
  2447.     Rbcs    L_IFonc
  2448.     cmp.w    #400,d1
  2449.     Rbhi    L_IFonc
  2450.     move.w    d1,48(a1)
  2451. IRd1    move.l    (a3)+,d1
  2452.     cmp.l    d0,d1
  2453.     beq.s    IRd2
  2454.     cmp.w    #65,d1
  2455.     Rbcs    L_IFonc
  2456.     cmp.w    #320,d1
  2457.     Rbhi    L_IFonc
  2458.     move.w    d1,50(a1)
  2459. IRd2    move.l    (a3)+,d1
  2460.     cmp.l    d0,d1
  2461.     beq.s    IRd3
  2462.     and.w    #$0001,d1
  2463.     move.w    d1,52(a1)
  2464. IRd3    move.l    (a3)+,d1
  2465.     cmp.l    d0,d1
  2466.     beq.s    IRd4
  2467.     and.w    #$0001,d1
  2468.     move.w    d1,54(a1)
  2469. IRd4    rts
  2470.  
  2471. ******* Narrator READ lips
  2472. L_LipsX        equ    9
  2473. L9    Dlea    ReadIo,a0
  2474.     moveq    #0,d2
  2475.     move.b    88(a0),d3
  2476.     ext.w    d3
  2477.     ext.l    d3
  2478.     rts
  2479. L_LipsY        equ    10
  2480. L10    Dlea    ReadIo,a0
  2481.     moveq    #0,d2
  2482.     move.b    89(a0),d3
  2483.     ext.w    d3
  2484.     ext.l    d3
  2485.     rts
  2486.  
  2487. ***********************************************************
  2488. *    MUSIC INSTRUCTION
  2489.  
  2490. *******    BELL
  2491. L_Bell0        equ    11
  2492. L11    moveq    #0,d3
  2493.     moveq    #70,d2
  2494.     moveq    #%1111,d1
  2495.     moveq    #1,d5
  2496.     Dlea    EnvBell,a0
  2497.     move.l    a0,d6
  2498.     Rbra    L_GoBel
  2499. L_Bell1        equ    12
  2500. L12    moveq    #0,d3
  2501.     move.l    (a3)+,d2
  2502.     moveq    #%1111,d1
  2503.     moveq    #1,d5
  2504.     Dlea    EnvBell,a0
  2505.     move.l    a0,d6
  2506.     Rbra    L_GoBel
  2507. ******* BOOM
  2508. L_Boom        equ    13
  2509. L13    moveq    #0,d3
  2510.     moveq    #36,d2
  2511.     moveq    #0,d5
  2512.     Dlea    EnvBoom,a0
  2513.     move.l    a0,d6
  2514.     Rbra    L_Shout
  2515. ******* SHOOT
  2516. L_Shoot        equ    14
  2517. L14    moveq    #0,d3
  2518.     moveq    #60,d2
  2519.     moveq    #0,d5
  2520.     Dlea    EnvShoot,a0
  2521.     move.l    a0,d6
  2522.     Rbra    L_Shout
  2523. * Gives a stereo effect
  2524. L_Shout:    equ    15
  2525. L15    moveq    #%0000,d0
  2526.     Rbsr    L_StopDma
  2527.     Rbsr    L_VOnOf
  2528.     moveq    #%1000,d1
  2529. Shot    movem.l    d0-d7,-(sp)
  2530.     Rbsr    L_GoShot
  2531.     movem.l    (sp)+,d0-d7
  2532.     addq.w    #1,d2
  2533.     lsr.w    #1,d1
  2534.     bcc.s    Shot
  2535.     rts
  2536.  
  2537. *******    VOLUME n
  2538. L_IVol1        equ    16
  2539. L16    move.l    (a3)+,d0
  2540.     moveq    #%1111,d1
  2541.     Rbsr    L_Vol
  2542.     Rbsr    L_MVol
  2543.     rts
  2544. ******* VOLUME voice,n
  2545. L_IVol2        equ    17
  2546. L17    move.l    (a3)+,d0
  2547.     move.l    (a3)+,d1
  2548.     Rbra    L_Vol
  2549. * Set voices volume level
  2550. L_Vol        equ    18
  2551. L18    cmp.l    #64,d0
  2552.     Rbcc    L_IFonc
  2553.     moveq    #0,d2
  2554.     Dlea    EnvBase,a0
  2555.     Dlea    Sami_int,a1
  2556. Vol1    btst    d2,d1
  2557.     beq.s    Vol2
  2558.     move.w    d0,EnvDVol(a0)
  2559.     tst.w    Sami_dvol(a1)
  2560.     bmi.s    Vol2
  2561.     move.w    d0,Sami_dvol(a1)
  2562. Vol2    lea    EnvLong(a0),a0
  2563.     lea    Sami_intl(a1),a1
  2564.     addq.w    #1,d2
  2565.     cmp.w    #4,d2
  2566.     bcs.s    Vol1
  2567.     rts
  2568.  
  2569. ******* Stops Narrator if it was playing in multitask mode!
  2570. L_NarStop    equ    19
  2571. L19    movem.l    a3/a6,-(sp)
  2572.     Dload    a3
  2573.     move.l    $4.w,a6
  2574.     move.l    WriteIo-MB(a3),d0
  2575.     beq.s    .Skip2
  2576.     move.l    d0,a1
  2577.     tst.b    66(a1)
  2578.     beq.s    .Skip2
  2579.     clr.b    66(a1)
  2580.     jsr    _LVOCheckIO(a6)
  2581.     tst.l    d0
  2582.     bne.s    .Skip1
  2583.     move.l    WriteIo-MB(a3),a1
  2584.     jsr    _LVOAbortIO(a6)
  2585. .Skip1    move.l    WriteIo-MB(a3),a1
  2586.     jsr    _LVOWaitIO(a6)
  2587.     Rbsr    L_Sami_Install
  2588. .Skip2    movem.l    (sp)+,a3/a6
  2589.     rts
  2590.  
  2591. *******    PLAY note,length
  2592. L_IPlay2    equ    20
  2593. L20    move.l    (a3)+,d3
  2594.     Rbmi    L_IFonc
  2595.     move.l    (a3)+,d2
  2596.     moveq    #%1111,d1
  2597.     moveq    #-1,d5
  2598.     moveq    #0,d6
  2599.     Rbra    L_GoBel
  2600. ******* Play voice,note,length
  2601. L_IPlay3    equ    21
  2602. L21    move.l    (a3)+,d3
  2603.     Rbmi    L_IFonc
  2604.     move.l    (a3)+,d2
  2605.     move.l    (a3)+,d1
  2606.     moveq    #-1,d5
  2607.     moveq    #0,d6
  2608.     Rbra    L_GoBel
  2609. L_GoBel        equ    22
  2610. L22    cmp.l    #96,d2            * <96?
  2611.     Rbhi    L_IFonc
  2612.     move.w    d1,d0            * Stop voices
  2613.     eor.w    #$000F,d0
  2614.     Rbsr    L_StopDma
  2615.     Rbsr    L_VOnOf
  2616.     Rbra    L_GoShot
  2617. L_GoShot    equ    23
  2618. L23    move.l    a3,-(sp)
  2619.     lea    Circuits,a2
  2620.     Dload    a3
  2621.     move.w    EnvOn-MB(a3),d7
  2622.     clr.w    EnvOn-MB(a3)
  2623.     move.w    #$8000,Sami_Bits-MB(a3)
  2624. * Explores all 4 voices
  2625.     moveq    #0,d0
  2626.     move.w    d1,d4
  2627.     moveq    #3,d1
  2628. IPl1    btst    d1,d4
  2629.     beq.s    IPl2
  2630.     Rbsr    L_VPlay
  2631. IPl2    dbra    d1,IPl1
  2632. ******* Start!
  2633. IPlX    Rbsr    L_DmaWait
  2634.     bset    #15,d0
  2635.     move.w    d0,DmaCon(a2)
  2636.     move.w    Sami_bits-MB(a3),IntEna(a2)
  2637.     move.w    d7,EnvOn-MB(a3)
  2638.     move.l    (sp)+,a3
  2639. * Wait?
  2640.     tst.l    d3
  2641.     beq.s    IPlX1
  2642.     Rjsr    L_WaitRout
  2643. IPlX1    rts
  2644.  
  2645. ******* Play voice D1: WAVE orSAMPLE
  2646. L_VPlay        equ    24
  2647. L24    movem.l    d0-d6/a0-a2,-(sp)
  2648.  
  2649.     moveq    #0,d3
  2650.     bset    d1,d3
  2651.     move.w    d3,DmaCon(a2)        * Stop voice
  2652.     lsl.w    #7,d3
  2653.     move.w    d3,IntEna(a2)        * Stop interrupts
  2654.     bclr    d1,Noise-MB(a3)        * No more random
  2655.     
  2656.     tst.w    d2
  2657.     beq    VSil
  2658.     addq.w    #3,d2
  2659.     move.w    d5,d0            * Forced wave? (bell)
  2660.     bpl.s    VPl0
  2661.     move.w    d1,d0            * Wave or Sample?
  2662.     lsl.w    #1,d0
  2663.     lea    Waves-MB(a3),a0
  2664.     move.w    0(a0,d0.w),d0
  2665.     bmi    VPl2
  2666.  
  2667. * Play WAVE!
  2668. VPl0    beq    VPl4
  2669.     lea    $a0(a2),a2
  2670.     move.w    d1,d3
  2671.     lsl.w    #4,d3
  2672.     add.w    d3,a2            * a2-> I/O
  2673.     movem.l    d1-d3/a2,-(sp)
  2674.     move.w    d0,d1
  2675.     Rbsr    L_WaveAd
  2676.     Rbeq    L_WNDef
  2677.     move.l    a2,a1
  2678.     movem.l    (sp)+,d1-d3/a2
  2679.     pea    WaveEnv(a1)
  2680.     lea    WaveDeb(a1),a1
  2681.     subq.w    #1,d2
  2682.     move.w    d2,d3
  2683.     ext.l    d3
  2684.     divu    #12,d3
  2685.     lsl.w    #2,d3
  2686.     lea    TFreq-MB(a3),a0
  2687.     add.w    d3,a0
  2688.     add.w    (a0)+,a1
  2689.     move.l    a1,(a2)            * AudAd
  2690.     move.w    (a0)+,d3
  2691.     move.w    d3,4(a2)        * AudLen
  2692.     lsl.w    #1,d3
  2693.     lea    TNotes-MB(a3),a1
  2694.     lsl.w    #1,d2
  2695.     mulu    0(a1,d2.w),d3
  2696.     move.l    MusClock-MB(a3),d2
  2697.     divu    d3,d2
  2698.     cmp.w    #124,d2
  2699.     bcc.s    VPl1
  2700.     moveq    #124,d2
  2701. VPl1:    move.w    d2,6(a2)        * AudPer
  2702. * Start enveloppe 
  2703.     move.l    (sp)+,d5
  2704.     tst.l    d6            * Fixed enveloppe? (bell / shoot)
  2705.     bne.s    VPl1a
  2706.     move.l    d5,d6
  2707. VPl1a    lea    EnvBase-MB(a3),a0    
  2708.     move.w    d1,d0
  2709.     mulu    #EnvLong,d0
  2710.     add.w    d0,a0
  2711.     move.l    d6,EnvAd(a0)
  2712.     move.l    d6,EnvDeb(a0)
  2713.     clr.w    EnvVol(a0)
  2714.     Rbsr    L_MuIntE
  2715.     movem.l    (sp)+,a0-a2/d0-d6
  2716.     bset    d1,d0
  2717.     bset    d1,d7
  2718.     rts
  2719. ******* Silence!
  2720. VSil    moveq    #0,d0
  2721.     bset    d1,d0
  2722.     move.w    d0,DmaCon(a2)
  2723.     movem.l    (sp)+,a0-a2/d0-d6
  2724.     bclr    d1,d7
  2725.     rts    
  2726. ******* Play SAMPLE
  2727. VPl2    move.l    a2,-(sp)
  2728.     move.w    d2,-(sp)
  2729.     neg.w    d0
  2730.     Rbsr    L_GetSam
  2731.     move.w    (sp)+,d0
  2732.     move.l    (sp)+,a2
  2733.     moveq    #0,d6
  2734. VPl3    lea    TNotes-MB(a3),a0
  2735.     lsl.w    #1,d0
  2736.     mulu    -2(a0,d0.w),d3
  2737.     divu    #440,d3
  2738.     and.l    #$0000FFFF,d3
  2739.     Rbra    L_SPl0
  2740. ******* Play NOISE
  2741. VPl4    bset    d1,Noise-MB(a3)
  2742.     move.w    d2,d0
  2743.     move.l    WaveBase-MB(a3),a1
  2744.     lea    WaveEnv(a1),a0
  2745.     lea    WaveDeb(a1),a1
  2746.     move.l    #LNoise,d2
  2747.     move.l    #2000,d3
  2748.     tst.l    d6
  2749.     bne.s    VPl3
  2750.     move.l    a0,d6
  2751.     bset    #0,d6
  2752.     bra.s    VPl3
  2753.  
  2754. ******* PLAY OFF (voice)
  2755. L_IPlOf0    equ    25
  2756. L25    moveq    #%1111,d0
  2757.     Rbra    L_PlOf
  2758. L_IPlOf1    equ    26
  2759. L26    move.l    (a3)+,d0
  2760.     Rbra    L_Plof
  2761. L_PlOf        equ    27
  2762. L27    move.l    a3,-(sp)
  2763.     Dload    a3
  2764.     Rbsr    L_EnvOff
  2765.     move.l    (sp)+,a3
  2766.     rts
  2767.  
  2768. ******* Attente DMA
  2769. L_DmaWait    equ    28
  2770. L28    movem.l    d2-d3,-(sp)
  2771.  
  2772. ; A modifier!!! Demander les caracteristiques du DMA!!!
  2773. ;    move.w    #$200,d0
  2774. ;.loop    nop
  2775. ;    dbra    d0,.loop
  2776.  
  2777. .wait    moveq    #4,d3        
  2778. .wai2    move.b    $dff006,d2    
  2779. .wai3    cmp.b    $dff006,d2    
  2780.     beq.s    .wai3
  2781.     dbf    d3,.wai2    
  2782.     moveq    #8,d2
  2783. .wai4    dbf    d2,.wai4
  2784.  
  2785.     movem.l    (sp)+,d2-d3
  2786.     rts
  2787.  
  2788. ***********************************************************
  2789. *    SAMPLE INSTRUCTIONS
  2790.  
  2791. *******    SAM BANK n
  2792. L_ISBank    equ    29
  2793. L29    move.l    (a3)+,d0
  2794.     Rbls    L_IFonc
  2795.     cmp.l    #16,d0
  2796.     Rbhi    L_IFonc
  2797.     Dlea    SamBank,a0
  2798.     move.w    d0,(a0)
  2799.     rts
  2800. ******* SAMLOOP ON
  2801. L_ISLOn1    equ    30
  2802. L30    moveq    #0,d0
  2803.     move.l    (a3)+,d1
  2804.     Rbra    L_Sl0
  2805.  
  2806. ******* STOP DMA / INTERUPTS
  2807. *    D0= value
  2808. L_StopDma    equ    31
  2809. L31    move.w    d0,-(sp)
  2810.     eor.w    #%1111,d0
  2811.     move.w    d0,Circuits+DmaCon
  2812.     lsl.w    #7,d0
  2813.     move.w    d0,Circuits+IntEna
  2814.     move.w    (sp)+,d0
  2815.     RBra    L_DmaWait
  2816.  
  2817. L_ISLOn0    equ    32
  2818. L32    moveq    #0,d0
  2819.     moveq    #%1111,d1
  2820.     Rbra    L_Sl0
  2821.  
  2822. ******* SAMLOOP OFF
  2823. L_ISLOf1    equ    33
  2824. L33    moveq    #-1,d0
  2825.     move.l    (a3)+,d1
  2826.     Rbra    L_Sl0
  2827. L_ISLOf0    equ    34
  2828. L34    moveq    #-1,d0
  2829.     moveq    #%1111,d1
  2830.     Rbra    L_SL0
  2831. L_SL0        equ    35
  2832. L35    moveq    #0,d2
  2833.     Dlea    Sami_int,a0
  2834.     Dlea    SamLoops+1,a1
  2835. Sl1    btst    d2,d1
  2836.     beq.s    Sl2
  2837.     bclr    d2,(a1)
  2838.     move.l    d0,Sami_rpos(a0)
  2839.     bne.s    Sl2
  2840.     bset    d2,(a1)
  2841. Sl2    lea    Sami_intl(a0),a0
  2842.     addq.w    #1,d2
  2843.     cmp.w    #4,d2
  2844.     bcs.s    Sl1
  2845.     rts
  2846.  
  2847. ******* NOISE TO voice
  2848. L_INoTo        equ    36
  2849. L36    move.l    (a3)+,d1
  2850.     moveq    #0,d0
  2851.     Rbra    L_ISmt
  2852. ******* SAMPLE n TO voice
  2853. L_ISamTo    equ    37
  2854. L37    move.l    4(a3),d0
  2855.     Rbsr    L_GetSam
  2856.     move.l    (a3)+,d1
  2857.     move.l    (a3)+,d0
  2858.     neg.w    d0
  2859.     Rbra    L_Ismt
  2860. * Poke D1-> waves
  2861. L_ISmt        equ    38
  2862. L38    Dlea    Waves,a0
  2863.     moveq    #0,d2
  2864. ISmt1    btst    d2,d1
  2865.     beq.s    ISmt2
  2866.     move.w    d0,(a0)
  2867. ISmt2    addq.l    #2,a0
  2868.     addq.w    #1,d2
  2869.     cmp.w    #4,d2
  2870.     bcs.s    ISmt1
  2871.     rts
  2872.  
  2873. ******* SAM PLAY number
  2874. L_ISam1        equ    39
  2875. L39    move.l    (a3)+,d0
  2876.     Rbsr    L_GetSam
  2877.     moveq    #%1111,d1
  2878.     Rbra    L_GoSam
  2879. ******* SAM PLAY voix,number
  2880. L_ISam2        equ    40
  2881. L40    move.l    (a3)+,d0
  2882.     Rbsr    L_GetSam
  2883.     move.l    (a3)+,d1
  2884.     Rbra    L_GoSam
  2885. ******* SAM PLAY voix,number,frequence
  2886. L_ISam3        equ    41
  2887. L41    move.l    4(a3),d0
  2888.     Rbsr    L_GetSam
  2889.     move.l    (a3)+,d3
  2890.     cmp.l    #500,d3
  2891.     Rble    L_IFonc
  2892.     addq.l    #4,a3
  2893.     move.l    (a3)+,d1    
  2894.     Rbra    L_GoSam
  2895. ******* SAM RAW voice,ad,length,freq
  2896. L_ISamR        equ    42
  2897. L42    move.l    (a3)+,d3
  2898.     cmp.l    #500,d3
  2899.     Rble    L_IFonc
  2900.     move.l    (a3)+,d2
  2901.     cmp.l    #256,d2
  2902.     Rble    L_IFonc
  2903.     move.l    (a3)+,a1
  2904.     move.l    (a3)+,d1
  2905.     Rbra    L_GoSam
  2906. L_GoSam:    equ    43
  2907. L43    move.l    a3,-(sp)
  2908.     Dload    a3
  2909.  
  2910.     move.w    d1,d0
  2911.     eor.w    #$000F,d0
  2912.     Rbsr    L_StopDma
  2913.     Rbsr    L_VOnOf    
  2914.  
  2915.     lea    Circuits,a2
  2916.     move.w    EnvOn-MB(a3),d7
  2917.     clr.w    EnvOn-MB(a3)
  2918.     move.w    #$8000,Sami_bits-MB(a3)
  2919. * Do all voices
  2920.     moveq    #0,d0
  2921.     move.w    d1,d4
  2922.     moveq    #3,d1
  2923. ISp2b    btst    d1,d4
  2924.     beq.s    ISp2c
  2925.     Rbsr    L_SPlay
  2926. ISp2c    dbra    d1,ISp2b
  2927. * Start!
  2928. ISpX    
  2929.     Rbsr    L_DmaWait
  2930.     bset    #15,d0
  2931.     move.w    d0,DmaCon(a2)
  2932.     move.w    Sami_bits-MB(a3),IntEna(a2)
  2933.     move.w    d7,EnvOn-MB(a3)
  2934.     move.l    (sp)+,a3
  2935.     rts
  2936.     
  2937. ******* Find a sample -> A0
  2938. L_GetSam    equ    44
  2939. L44    move.l    d0,-(sp)
  2940.     Dload    a0
  2941.     move.w    SamBank-MB(a0),d0
  2942.     ext.l    d0
  2943.     Rbeq    L_IFonc
  2944.     move.l    d1,-(sp)
  2945.     Rjsr    L_Bnk.GetAdr
  2946.     Rbeq    L_BNSam
  2947.     move.l    (sp)+,d1
  2948.     move.l    -8(a0),d0
  2949.     cmp.l    #"Samp",d0
  2950.     Rbne    L_BNSam
  2951. * Get sample characteristics1
  2952.     move.l    (sp)+,d0
  2953.     Rbls    L_IFonc
  2954.     cmp.w    (a0),d0
  2955.     Rbhi    L_SNDef
  2956.     lsl.w    #2,d0
  2957.     move.l    2-4(a0,d0.w),d0
  2958.     Rbeq    L_SNDef
  2959.     add.l    d0,a0
  2960.     moveq    #0,d3
  2961.     move.w    8(a0),d3
  2962.     move.l    10(a0),d2
  2963.     lea    14(a0),a1
  2964.     rts
  2965.  
  2966. *********************************************************************
  2967. *    SLOAD fichier,adresse,longueur
  2968. L_Sload        equ    45
  2969. L45    move.l    (a3)+,d3        Length
  2970.     RBmi    L_IFonc    
  2971.     move.l    (a3)+,d0        Adress (or bank)
  2972.     RJsr    L_Bnk.OrAdr
  2973.     move.l    d0,d2
  2974.     move.l    (a3)+,d0        File
  2975.     cmp.l    #10,d0
  2976.     Rbcc    L_IFonc
  2977.     subq.l    #1,d0
  2978.     Rbmi    L_IFonc
  2979.     mulu    #TFiche,d0
  2980.     lea    Fichiers(a5),a2
  2981.     add.w    d0,a2
  2982.     move.l    Fha(a2),d1
  2983.     RBeq    L_IFonc
  2984.     btst    #2,FhT(a2)
  2985.     Rbne    L_IFonc
  2986. * Load the data
  2987.     move.l    a6,-(sp)
  2988.     move.l    DosBase(a5),a6
  2989.     jsr    -42(a6)            DosRead
  2990.     move.l    (sp)+,a6
  2991.     tst.l    d0
  2992.     RBmi    L_IDError
  2993.     rts
  2994.  
  2995. ******* SAMPLAY routine
  2996. *    A1= Sample
  2997. *    D3= Freq
  2998. *    D2= Long
  2999. *    D1= Voice
  3000. L_SPlay:    equ    46
  3001. L46    movem.l    d0-d6/a0-a2,-(sp)
  3002.     bclr    d1,Noise-MB(a3)
  3003.     moveq    #0,d6
  3004.     Rbra    L_SPl0
  3005.  
  3006. L_SPl0        equ    47
  3007. L47
  3008.     movem.l    a4,-(sp)
  3009.  
  3010.     moveq    #0,d0
  3011.     bset    d1,d0            * Stop voice
  3012.     move.w    d0,DmaCon(a2)
  3013.  
  3014.     lea    Sami_int-MB(a3),a4
  3015.     move.w    #Sami_intl,d0
  3016.     mulu    d1,d0
  3017.     add.w    d0,a4            * a4-> Sami interrupts
  3018.     move.w    Sami_bit(a4),IntEna(a2)    * No more interrupts
  3019.  
  3020.     lea    EnvBase-MB(a3),a0    * Enveloppe
  3021.     move.w    d1,d0
  3022.     mulu    #EnvLong,d0
  3023.     add.w    d0,a0
  3024.  
  3025.     lea    $a0(a2),a2
  3026.     move.w    d1,d4
  3027.     lsl.w    #4,d4
  3028.     add.w    d4,a2            * a2-> I/O
  3029.  
  3030.     move.w    #1,$4(a2)
  3031.     move.l    a1,Sami_adr(a4)            * Adresse
  3032.     move.l    d2,Sami_long(a4)        * Longueur
  3033.     clr.l    Sami_pos(a4)            * Position
  3034.     clr.l    Sami_rpos(a4)            * Sam loop on?
  3035.     btst    d1,SamLoops+1-MB(a3)
  3036.     bne.s    .skipa
  3037.     subq.l    #1,Sami_rpos(a4)
  3038. .skipa    clr.l    Sami_radr(a4)            * Pas de double buffer
  3039.     
  3040.     move.l    d6,d5
  3041.     move.l    MusClock-MB(a3),d6
  3042.     bsr    Div32
  3043.     cmp.l    #124,d0
  3044.     bcc.s    .skip0
  3045.     moveq    #124,d0
  3046. .skip0    move.w    d0,6(a2)            * AudPer
  3047.  
  3048.     bclr    d1,d7
  3049.     move.w    EnvDVol(a0),Sami_dvol(a4)    * Volume, sauf si 
  3050.     tst.l    d5                  une enveloppe est
  3051.     beq.s    .skip1                  definie
  3052.     clr.l    Sami_rpos(a4)
  3053.     bclr    #0,d5
  3054.     bne.s    .skipb
  3055.     subq.l    #1,Sami_rpos(a4)
  3056. .skipb    bset    d1,d7
  3057.     move.w    #-1,Sami_dvol(a4)
  3058.     move.l    d5,EnvAd(a0)
  3059.     move.l    d5,EnvDeb(a0)
  3060.     clr.w    EnvVol(a0)
  3061.     Rbsr    L_MuIntE
  3062.  
  3063. .skip1    move.w    Sami_bit(a4),d0
  3064.     or.w    d0,Sami_bits-MB(a3)
  3065.  
  3066. * Va demarrer le son...
  3067.     lea    Circuits,a0
  3068.     move.l    a4,a1
  3069.     move.l    Sami_Handad-MB(a3),a2
  3070.     jsr    (a2)
  3071. * Fini!
  3072.     move.l    (sp)+,a4
  3073.     movem.l    (sp)+,d0-d6/a0-a2
  3074.     bset    d1,d0
  3075.     rts
  3076.  
  3077. * Division 32 bits
  3078. * D6/D3 -> D0
  3079. Div32    movem.l    d1/d3/d4/d5/d6,-(sp)
  3080.     moveq     #31,d5
  3081.         moveq     #-1,d4
  3082.         clr.l     d1
  3083. dv2:    lsl.l     #1,d6
  3084.         roxl.l     #1,d1
  3085.         cmp.l     d3,d1
  3086.         bcs.s     dv1
  3087.         sub.l     d3,d1
  3088.         lsr     #1,d4
  3089. dv1:    roxl.l     #1,d0
  3090.         dbra     d5,dv2
  3091.     movem.l    (sp)+,d1/d3/d4/d5/d6
  3092.     rts
  3093.  
  3094. ***********************************************************
  3095. *    WAVE INSTRUCTION SET
  3096.  
  3097. *******    WAVE n TO n
  3098. L_IWave:    equ    48
  3099. L48    move.l    4(a3),d1
  3100.     Rbmi    L_IFonc
  3101.     Rbsr    L_WaveAd
  3102.     Rbeq    L_WNDef
  3103.     move.l    (a3)+,d1
  3104.     move.l    (a3)+,d0
  3105.     Rbra    L_ISmt
  3106. *******    SET WAVE n,a$
  3107. L_ISWave:    equ    49
  3108. L49    move.l    (a3)+,a1
  3109.     move.w    (a1)+,d1
  3110.     cmp.w    #256,d1
  3111.     Rbcs    L_STSho
  3112.     move.l    (a3)+,d1
  3113.     Rbls    L_IFonc
  3114.     move.l    a3,-(sp)
  3115.     Dload    a3
  3116.     Rbsr    L_NeWave
  3117.     Rbne    L_IOOMem
  3118.     move.l    (sp)+,a3
  3119.     rts
  3120. *******    DEL WAVE 
  3121. L_IDWave1    equ    50
  3122. L50    move.l    (a3)+,d1
  3123.     Rbmi    L_IFonc
  3124.     Rbeq    L_W0Res
  3125.     cmp.l    #1,d1
  3126.     Rbeq    L_W0Res
  3127.     move.l    a3,-(sp)
  3128.     DLoad    a3
  3129.     moveq    #%1111,d0
  3130.     Rbsr    L_EnvOff
  3131.     Rbsr    L_WaveAd
  3132.     Rbeq    L_WNDef
  3133.     Rbsr    L_WaveDel
  3134.     Rbsr    L_NoWave
  3135.     move.l    (sp)+,a3
  3136.     rts
  3137. *******    SET ENVEL n,n TO n,v
  3138. L_ISEnv        equ    51
  3139. L51    move.l    (a3)+,d4
  3140.     cmp.l    #64,d4
  3141.     Rbcc    L_IFonc
  3142.     move.l    (a3)+,d3
  3143.     move.l    (a3)+,d5
  3144.     Rbmi    L_IFonc
  3145.     cmp.l    #7,d5
  3146.     Rbcc    L_IFonc
  3147.     move.l    (a3)+,d1
  3148.     Rbmi    L_IFonc
  3149.     tst.w    d5
  3150.     bne.s    ISe1
  3151.     tst.w    d3
  3152.     Rbls    L_IFonc
  3153. ISe1    move.l    a3,-(sp)
  3154.     Dload    a3
  3155.     Rbsr    L_WaveAd
  3156.     Rbeq    L_WNDef
  3157.     lsl.w    #2,d5
  3158.     lea    WaveEnv(a2,d5.w),a2
  3159.     move.w    d3,(a2)+
  3160.     move.w    d4,(a2)+
  3161.     clr.w    (a2)
  3162.     move.l    (sp)+,a3
  3163.     rts
  3164. ******* RAZ WAVES
  3165. L_RazWave    equ    52
  3166. L52    movem.l    a2/d0-d2,-(sp)
  3167.     moveq    #%1111,d0
  3168.     Rbsr    L_EnvOff        * Stop all voices
  3169.     lea    WaveBase-MB(a3),a2    * Erase all instruments
  3170.     move.l    a2,d2
  3171. RzW1    move.l    d2,a2
  3172.     move.l    (a2),d0
  3173.     beq.s    RzW2
  3174.     move.l    d0,a2
  3175.     Rbsr    L_WaveDel
  3176.     bra.s    RzW1
  3177. RzW2    Rbsr    L_NoWave
  3178.     movem.l    (sp)+,a2/d0-d2
  3179.     rts
  3180. * Plus de Waves speciales
  3181. L_NoWave    equ    53
  3182. L53    Dlea    Waves,a0        * Default waves
  3183.     move.w    #1,(a0)+
  3184.     move.w    #1,(a0)+
  3185.     move.w    #1,(a0)+
  3186.     move.w    #1,(a0)+
  3187.     rts
  3188.  
  3189. ******* NEW WAVES
  3190. *    A1= Array address
  3191. *    D1= # to create
  3192. L_NeWave:    equ    54
  3193. L54    movem.l    d1-d7/a1-a2,-(sp)
  3194. NeW0    Rbsr    L_WaveAd
  3195.     beq.s    NeW1
  3196.     moveq    #%1111,d0
  3197.     Rbsr    L_EnvOff
  3198.     Rbsr    L_WaveDel
  3199.     bra.s    NeW0
  3200. NeW1    move.l    #WaveLong,d0
  3201.     RJsr    L_RamChip
  3202.     beq.s    NeWE
  3203.     move.l    d0,(a2)
  3204.     move.l    d0,a2
  3205.     move.w    d1,WaveNb(a2)
  3206. * Copy default ADSR
  3207.     move.l    a1,-(sp)
  3208.     lea    EnvDef-MB(a3),a0
  3209.     lea    WaveEnv(a2),a1
  3210. NeW3    move.l    (a0)+,(a1)+
  3211.     bne.s    NeW3
  3212.     move.l    (sp)+,a1
  3213. * Full wave: 256 bytes
  3214.     lea    WaveDeb(a2),a2
  3215.     move.l    a2,a0
  3216.     moveq    #256/4-1,d0
  3217. NeW2    move.l    (a1)+,(a0)+
  3218.     dbra    d0,NeW2
  3219. * 1/2
  3220.     move.l    a2,a1
  3221.     move.l    a0,a2
  3222.     moveq    #127,d0
  3223.     bsr    NewRout
  3224. * 1/4
  3225.     move.l    a2,a1
  3226.     move.l    a0,a2
  3227.     moveq    #63,d0
  3228.     bsr    NewRout
  3229. * 1/8
  3230.     move.l    a2,a1    
  3231.     move.l    a0,a2
  3232.     moveq    #31,d0
  3233.     bsr    NewRout
  3234. * 1/16
  3235.     move.l    a2,a1
  3236.     move.l    a0,a2
  3237.     moveq    #15,d0
  3238.     bsr    NewRout
  3239. * 1/32
  3240.     move.l    a2,a1
  3241.     move.l    a0,a2
  3242.     moveq    #7,d0
  3243.     bsr    NewRout
  3244. * 1/64
  3245.     move.l    a2,a1
  3246.     move.l    a0,a2
  3247.     moveq    #3,d0
  3248.     bsr    NewRout
  3249. ******* No error
  3250.     moveq    #0,d0
  3251. NeWx    movem.l    (sp)+,d1-d7/a1-a2
  3252.     rts
  3253. ******* Out of mem
  3254. NeWE    moveq    #-1,d0
  3255.     bra.s    NeWx
  3256. ******* Divide a sample by 2
  3257. NewRout    move.b    (a1)+,d1
  3258.     ext.w    d1
  3259.     move.b    (a1)+,d2
  3260.     ext.w    d2
  3261.     add.w    d2,d1
  3262.     asr.w    #1,d1
  3263.     move.b    d1,(a0)+
  3264.     dbra    d0,NewRout
  3265.     rts
  3266.  
  3267. ******* Get a wave address
  3268. L_WaveAd:    equ    55
  3269. L55    moveq    #0,d2
  3270.     Dlea    WaveBase,a2
  3271.     move.l    (a2),d0
  3272.     beq.s    WAd2
  3273. WAd1    move.l    a2,d2
  3274.     move.l    d0,a2
  3275.     cmp.w    WaveNb(a2),d1
  3276.     beq.s    WAd3
  3277.     move.l    (a2),d0
  3278.     bne.s    WAd1
  3279. WAd2    moveq    #0,d0
  3280.     rts
  3281. WAd3    moveq    #-1,d0
  3282.     rts
  3283.  
  3284. ******* Deletion of a WAVE (A2)-D2
  3285. L_WaveDel    equ    56
  3286. L56    movem.l    a0-a2/d0-d2,-(sp)
  3287.     move.w    WaveNb(a2),d1
  3288.     move.l    d2,a0
  3289.     move.l    (a2),(a0)
  3290.     move.l    #WaveLong,d0
  3291.     move.l    a2,a1
  3292.     Rjsr    L_RamFree
  3293.     movem.l    (sp)+,a0-a2/d0-d2
  3294.     rts
  3295.  
  3296. ***********************************************************
  3297. *    STOP SAMPLES INTERRUPTS
  3298. L_Sami_stop    equ    57
  3299. L57    move.w    #%0000011110000000,d0
  3300.     move.w    d0,Circuits+IntEna
  3301.     move.w    d0,Circuits+IntReq
  3302.     rts
  3303.  
  3304. ***********************************************************
  3305. *    ENVELOPPES 
  3306.  
  3307. ***********************************************************
  3308. *    STOP ENVELOPPE D0
  3309. L_EnvOff    equ    58
  3310. L58    movem.l    d0-d3/a0,-(sp)
  3311.     move.w    EnvOn-MB(a3),d1
  3312.     clr.w    EnvOn-MB(a3)
  3313.     moveq    #0,d3
  3314.     lea    Circuits,a0
  3315.     moveq    #0,d2
  3316. EOf1    btst    d2,d0
  3317.     beq.s    EOf2
  3318.     bclr    d2,d1
  3319.     beq.s    EOf2
  3320.     bset    d2,d3
  3321.     move.w    #2,$a4(a0)
  3322.     clr.w    $a8(a0)
  3323. EOf2    lea    $10(a0),a0
  3324.     addq.w    #1,d2
  3325.     cmp.w    #4,d2
  3326.     bcs.s    EOf1
  3327.     move.w    d1,EnvOn-MB(a3)
  3328.     move.w    d3,MuReStart-MB(a3)
  3329.     movem.l    (sp)+,d0-d3/a0
  3330.     rts
  3331.     
  3332. ******* Next enveloppe
  3333. L_MuIntE    equ    59
  3334. L59    move.l    EnvAd(a0),a1
  3335. MuIe0    move.w    (a1)+,d3
  3336.     beq.s    MuIntS
  3337.     bmi.s    MuIe1
  3338.     move.w    d3,EnvNb(a0)
  3339.     move.w    EnvDVol(a0),d4
  3340.     mulu    (a1)+,d4
  3341.     lsr.w    #6,d4
  3342.     sub.w    EnvVol(a0),d4
  3343.     ext.l    d4
  3344.     lsl.w    #8,d4
  3345.     divs    d3,d4
  3346.     ext.l    d4
  3347.     lsl.l    #8,d4
  3348.     move.l    d4,EnvDelta(a0)
  3349.     clr.w    EnvVol+2(a0)
  3350.     move.l    a1,EnvAd(a0)
  3351.     rts
  3352. * Loop
  3353. MuIe1    move.l    EnvDeb(a0),a1
  3354.     bra.s    MuIe0
  3355. * End of a voice
  3356. MuIntS    bset    d1,d5
  3357.     bclr    d1,d0
  3358.     bclr    d1,Noise-MB(a3)
  3359. * Restarts the music
  3360.     bset    d1,MuReStart+1-MB(a3)
  3361.     rts
  3362.  
  3363. ******************************************************************
  3364. *    MUSIC
  3365.  
  3366. ******* Music initialisation
  3367. L_MuInit:    equ    60
  3368. L60    clr.l    MuBase-MB(a3)
  3369.     clr.w    MuNumber-MB(a3)
  3370.     move.l    #$DFF0A0,MuChip0-MB(a3)
  3371.     move.l    #$DFF0B0,MuChip1-MB(a3)
  3372.     move.l    #$DFF0C0,MuChip2-MB(a3)
  3373.     move.l    #$DFF0D0,MuChip3-MB(a3)
  3374.     move.w    #$000F,MuDMAsk-MB(a3)
  3375.     clr.w    MuReStart-MB(a3)
  3376.     Rbra    L_MOff
  3377.  
  3378. ******* MUSIC OFF-> Stops all musics
  3379. L_IMuSOff    equ    61
  3380. L61    movem.l    a0-a3/d0-d1,-(sp)
  3381.     Dload    a3
  3382.     clr.l    MuBase-MB(a3)
  3383.     clr.w    MuNumber-MB(a3)
  3384.     Rbsr    L_MOff
  3385.     movem.l    (sp)+,a0-a3/d0-d1
  3386.     rts
  3387.  
  3388. ******* MUSIC STOP-> Stops current music
  3389. L_IMuStop    equ    62
  3390. L62    movem.l    a0-a3/d0-d1,-(sp)
  3391.     Dload    a3
  3392.     move.l    MuBase-MB(a3),d0
  3393.     beq.s    IStp
  3394.     clr.w    MuBase-MB(a3)
  3395.     move.l    d0,a0
  3396.     clr.w    VoiCpt0(a0)
  3397.     clr.w    VoiCpt1(a0)
  3398.     clr.w    VoiCpt2(a0)
  3399.     clr.w    VoiCpt3(a0)
  3400.     move.l    d0,MuBase-MB(a3)
  3401. IStp    movem.l    (sp)+,a0-a3/d0-d1
  3402.     rts
  3403.  
  3404. ******* MUSIC VOLUME
  3405. L_IMVol        equ    63
  3406. L63    move.l    (a3)+,d0
  3407.     cmp.l    #64,d0
  3408.     Rbcs    L_MVol
  3409.     Rbcc    L_IFonc
  3410. * Set volume
  3411. L_MVol        equ    64
  3412. L64    and.w    #63,d0
  3413.     Dload    a0
  3414.     move.w    d0,MuVolume-MB(a0)
  3415.     move.l    MuBase-MB(a0),d4
  3416.     beq.s    MVol3
  3417.     clr.l    MuBase-MB(a0)
  3418.     lea    MuBuffer-MB(a0),a1
  3419.     move.w    MuNumber-MB(a0),d1
  3420. MVol0    move.l    a1,a2
  3421.     moveq    #3,d2
  3422. MVol1    move.w    VoiDVol(a2),d3
  3423.     mulu    d0,d3
  3424.     lsr.w    #6,d3
  3425.     move.w    d3,VoiVol(a2)
  3426.     lea    VoiLong(a2),a2
  3427.     dbra    d2,MVol1
  3428. MVol2    lea    MuLong(a1),a1
  3429.     subq.w    #1,d1
  3430.     bne.s    MVol0
  3431.     move.l    d4,MuBase-MB(a0)
  3432. MVol3    rts
  3433.  
  3434. ******* VOICE ON/OFF Voices
  3435. L_IVoice    equ    65
  3436. L65    move.l    (a3)+,d0
  3437.     and.w    #$000F,d0
  3438.     move.l    a3,-(sp)
  3439.     Dload    a3
  3440.     Rbsr    L_VOnOf
  3441.     movem.l    (sp)+,a3
  3442.     rts
  3443.  
  3444. ******* Start / Stop voices D0
  3445. L_VOnOf        equ    66
  3446. L66    movem.l    d0-d5/a0-a3,-(sp)
  3447.     move.w    d0,d4
  3448.     Dload    a3
  3449.     move.l    MuBase-MB(a3),d1
  3450.     beq.s    VooX
  3451.     clr.l    MuBase-MB(a3)
  3452.     move.l    d1,a1
  3453.     move.l    d1,a2
  3454.     move.w    MuDMAsk-MB(a3),d1
  3455.     move.w    d0,MuDMAsk-MB(a3)
  3456.     move.l    WaveBase-MB(a3),a0
  3457.     lea    WaveDeb(a0),a0
  3458.     move.l    a0,d3
  3459.     lea    MuChip0-MB(a3),a0
  3460.     moveq    #0,d2
  3461.     moveq    #0,d4
  3462. * Exploration loop
  3463. Voo1    btst    d2,d0
  3464.     bne.s    Voo2
  3465. * Stop a voice!
  3466.     btst    d2,d1            * Already stopped?
  3467.     beq.s    VooN
  3468.     bset    d2,d4
  3469.     move.l    d3,(a0)
  3470.     bclr    d2,MuStart+1(a2)
  3471.     bclr    d2,MuStop+1(a2)
  3472.     bra.s    VooN
  3473. * Re start a voice
  3474. Voo2    btst    d2,d1            * Already on?
  3475.     bne.s    VooN
  3476.     bset    d2,MuReStart+1-MB(a3)
  3477. * Next
  3478. VooN    addq.l    #4,a0
  3479.     lea    VoiLong(a1),a1
  3480.     addq.w    #1,d2
  3481.     cmp.w    #4,d2
  3482.     bcs.s    Voo1
  3483. * Stop them!
  3484.     move.l    a2,MuBase-MB(a3)
  3485.     move.w    d4,Circuits+DmaCon
  3486. VooX    movem.l    (sp)+,d0-d5/a0-a3
  3487.     rts
  3488.  
  3489. ******* MUSIC n
  3490. L_IMusic    equ    67
  3491. L67    move.l    (a3)+,d3
  3492.     Rbls    L_IFonc
  3493. * Points to the SONG
  3494.     move.l    a3,-(sp)
  3495.     Dload    a3
  3496.     tst.l    MusBank-MB(a3)
  3497.     Rbeq    L_MnRes
  3498.     move.l    BankSong-MB(a3),a1
  3499.     cmp.w    (a1),d3
  3500.     Rbhi    L_MNDef
  3501.     lsl.w    #2,d3
  3502.     add.l    2-4(a1,d3.w),a1
  3503. * Still room?
  3504.     cmp.w    #3,MuNumber-MB(a3)
  3505.     bcc    IMusX
  3506.     clr.l    MuBase-MB(a3)
  3507. * Buffer address
  3508.     move.w    MuNumber-MB(a3),d0
  3509.     move.w    d0,d1
  3510.     addq.w    #1,MuNumber-MB(a3)
  3511.     mulu    #MuLong,d0
  3512.     lea    MuBuffer-MB(a3),a2
  3513.     add.w    d0,a2
  3514. * Init datas
  3515.     moveq    #(VoiLong*4)/2-1,d0
  3516.     move.l    a2,a0
  3517. IMus1    clr.w    (a0)+
  3518.     dbra    d0,IMus1
  3519.     clr.w    MuStop(a2)
  3520.     clr.w    MuStart(a2)
  3521. * Init parameters
  3522.     move.l    a2,d2
  3523.     move.w    TempoBase-MB(a3),MuCpt(a2)
  3524.     move.w    #17,MuTempo(a2)            *XXX
  3525.     moveq    #0,d0
  3526. IMus2    move.w    #1,VoiCpt(a2)
  3527.     lea    FoEnd-MB(a3),a0
  3528.     move.l    a0,VoiAdr(a2)
  3529.     move.l    a1,a0
  3530.     add.w    0(a0,d0.w),a0
  3531.     move.l    a0,VoiPat(a2)
  3532.     move.l    a0,VoiDPat(a2)
  3533.     lea    NoEffect2(pc),a0
  3534.     move.l    a0,VoiEffect(a2)
  3535.     lea    VoiLong(a2),a2
  3536.     addq.w    #2,d0
  3537.     cmp.w    #8,d0
  3538.     bne.s    IMus2
  3539. * No more samples
  3540.     move.w    #%0000011110000000,Circuits+IntEna
  3541. * Starts music
  3542.     move.l    d2,MuBase-MB(a3)
  3543. IMusX    move.l    (sp)+,a3
  3544.     rts
  3545. NoEffect2
  3546.     move.w    VoiNote(a4),$06(a6)
  3547.     rts
  3548.  
  3549. ******* Tempo T
  3550. L_ITempo    equ    68
  3551. L68    move.l    (a3)+,d0
  3552.     cmp.l    #100,d0
  3553.     Rbhi    L_IFonc
  3554.     Dload    a0
  3555.     move.l    MuBase-MB(a0),d1
  3556.     beq.s    ITemp
  3557.     move.l    d1,a0
  3558.     move.w    d0,MuTempo(a0)
  3559. ITemp    rts
  3560.  
  3561. ***********************************************************
  3562. *    =VU METRE(v)
  3563. L_FVu        equ    69
  3564. L69    move.l    (a3)+,d0
  3565.     cmp.l    #4,d0
  3566.     Rbcc    L_IFonc
  3567.     Dload    a0
  3568.     moveq    #0,d3
  3569.     move.b    0(a0,d0.w),d3
  3570.     clr.b    0(a0,d0.w)
  3571.     moveq    #0,d2
  3572.     rts
  3573.  
  3574. ***********************************************************
  3575. *    =MU BASE
  3576. L_FMB        equ    70
  3577. L70    Dload    a0
  3578.     move.l    a0,d3
  3579.     moveq    #0,d2
  3580.     rts
  3581.  
  3582. ***********************************************************
  3583. *    LED INSTRUCTION
  3584. L_LedOn        equ    71
  3585. L71    bclr    #1,$BFE001
  3586.     rts
  3587. L_LedOf        equ    72
  3588. L72    bset    #1,$BFE001
  3589.     rts
  3590.  
  3591. ***********************************************************
  3592. *    INSTALL THE SAMPLE HANDLER
  3593. L_Sami_install    equ    73
  3594. L73    tst.w    Sami_flag-MB(a3)
  3595.     bne.s    .skip
  3596.     movem.l    d0-d2/a0-a2/a6,-(sp)
  3597.     move.l    $4.w,a6
  3598. ; Save state of interrupts
  3599.     move.w    Circuits+IntEnaR,d0
  3600.     and.w    #%0000011110000000,d0
  3601.     move.w    d0,Sami_OldEna-MB(a3)
  3602.     Rbsr    L_Sami_stop
  3603. ; Install 4 voices
  3604.     lea    Sami_int-MB(a3),a1
  3605.     moveq    #7,d0
  3606. .loop    bsr.s    Sami_start
  3607.     lea    Sami_intl(a1),a1
  3608.     addq.w    #1,d0
  3609.     cmp.w    #11,d0
  3610.     bne.s    .loop
  3611.     subq.w    #1,Sami_flag-MB(a3)
  3612.     movem.l    (sp)+,d0-d2/a0-a2/a6
  3613. .skip    rts
  3614. Sami_start
  3615.     move.l    a1,is_data(a1)
  3616.     move.l    Sami_handad-MB(a3),is_code(a1)
  3617.     move.b    #2,ln_type(a1)
  3618.     move.b    #0,ln_pri(a1)
  3619.     move.l    $4.w,a6    
  3620.     movem.l    d0/a1,-(sp)
  3621.     jsr    -162(a6)        SetIntVector
  3622.     move.l    d0,d1
  3623.     movem.l    (sp)+,d0/a1
  3624.     move.l    d1,Sami_old(a1)
  3625.     rts
  3626.  
  3627. ***********************************************************
  3628. *    REMOVE THE SAMPLE HANDLER
  3629. L_Sami_remove    equ    74
  3630. L74    tst.w    Sami_flag-MB(a3)
  3631.     beq.s    .skip
  3632.     movem.l    a0-a2/a6/d0-d2,-(sp)
  3633.     Rbsr    L_Sami_Stop
  3634.     move.l    $4.w,a6
  3635.     moveq    #7,d2
  3636.     lea    Sami_Int-MB(a3),a2
  3637. .loop    move.l    Sami_old(a2),a1
  3638.     move.l    d2,d0
  3639.     jsr    -162(a6)        SetIntVector
  3640.     lea    Sami_intl(a2),a2
  3641.     addq.w    #1,d2    
  3642.     cmp.w    #11,d2
  3643.     bne.s    .loop
  3644.     lea    Circuits,a0
  3645.     move.w    #$000F,DmaCon(a0)
  3646.     move.w    Sami_oldena-MB(a3),IntEna(a0)
  3647.     clr.w    Sami_flag-MB(a3)
  3648.     movem.l    (sp)+,a0-a2/a6/d0-d2
  3649. .skip    rts
  3650.  
  3651. ***********************************************************
  3652. *    Normal error messages
  3653. ; This routines performs jump to the normal AMOS error messages:
  3654. ; Load in D0 the number of the error, and do a RJmp to L_Error.
  3655. L_IOOMem    equ    75
  3656. L75    
  3657.     moveq    #24,d0
  3658.     Rjmp    L_Error
  3659. L_IFonc        equ    76
  3660. L76    moveq    #23,d0
  3661.     Rjmp    L_Error
  3662.  
  3663. ***********************************************************
  3664. *     Customized error messages
  3665. ; This list of routines just load in D0 the number of the error message in
  3666. ; the extension error-list, and call the error handling routine.
  3667.  
  3668. L_WNDef        equ    77
  3669. L77    moveq    #0,d0    
  3670.     Rbra    L_Custom
  3671. L_SNDef        equ    78
  3672. L78    moveq    #1,d0
  3673.     Rbra    L_Custom
  3674. L_BNSam        equ    79
  3675. L79    moveq    #2,d0
  3676.     Rbra    L_Custom
  3677. L_STSho        equ    80
  3678. L80    moveq    #3,d0
  3679.     Rbra    L_Custom
  3680. L_W0Res        equ    81
  3681. L81    moveq    #4,d0
  3682.     Rbra    L_Custom
  3683. L_MnRes        equ    82
  3684. L82    moveq    #5,d0
  3685.     Rbra    L_Custom
  3686. L_MNDef        equ    83
  3687. L83    moveq    #6,d0
  3688.     Rbra    L_Custom
  3689.  
  3690.  
  3691. ********************************************************************
  3692. *    =SAM SWAPPED(V)
  3693. L_Samswapped    equ    84
  3694. L84    move.l    (a3)+,d0
  3695.     moveq    #0,d2
  3696.     moveq    #0,d3
  3697.     cmp.l    #3,d0
  3698.     Rbhi    L_IFonc
  3699.     move.w    Circuits+IntEnaR,d1
  3700.     lsr.w    #7,d1
  3701.     btst    d0,d1
  3702.     beq.s    .stop
  3703.     Dlea    Sami_int,a0
  3704.     mulu    #Sami_intl,d0
  3705.     tst.l    Sami_radr(a0,d0.l)
  3706.     bne.s    .skip
  3707.     move.l    Sami_pos(a0,d0.l),d1
  3708.     cmp.l    #Sami_lplay,d1
  3709.     beq.s    .skip
  3710.     moveq    #-1,d3
  3711. .skip    rts
  3712. .stop    moveq    #1,d3
  3713.     rts
  3714. *********************************************************************
  3715. *    SAM SWAP
  3716. L_SamSwap    equ    85
  3717. L85    move.l    (a3)+,d4
  3718.     Rbmi    L_IFonc
  3719.     move.l    (a3)+,d0
  3720.     Rjsr    L_Bnk.OrAdr
  3721.     move.l    d0,d3
  3722.     move.l    (a3)+,d2
  3723.     moveq    #0,d1
  3724.     Dlea    Sami_int,a0
  3725. .loop    btst    d1,d2
  3726.     beq.s    .skip
  3727.     move.l    d3,Sami_radr(a0)
  3728.     move.l    d4,Sami_rlong(a0)
  3729. .skip    lea    Sami_intl(a0),a0
  3730.     addq.w    #1,d1
  3731.     cmp.w    #4,d1
  3732.     bne.s    .loop
  3733.     rts
  3734. *********************************************************************
  3735. *    SAM STOP
  3736. L_SamStop0    equ    86
  3737. L86    move.l    #$f,-(a3)
  3738.     RBra    L_SamStop1
  3739. L_SamStop1    equ    87
  3740. L87    move.l    (a3)+,d1
  3741.     and.l    #$F,d1
  3742.     move.w    d1,Circuits+DmaCon
  3743.     lsl.w    #7,d1    
  3744.     move.w    d1,Circuits+IntEna
  3745.     rts
  3746.  
  3747. *********************************************************************
  3748. *    TRACKER instructions
  3749.  
  3750. *******    TRACK LOAD "nom",banque
  3751. L_Trackload    equ    88
  3752. L88    
  3753.     move.l    (a3)+,d3
  3754.     cmp.l    #$10000,d3
  3755.     Rbge    L_IFonc
  3756.     Dload    a0
  3757.     cmp.w    Track_Bank-MB(a0),d3
  3758.     bne.s    .kkk
  3759.     tst.b    mt_on-MB(a0)
  3760.     beq.s    .kkk
  3761.     RBsr    L_TrackStop
  3762. .kkk    move.w    d3,Track_Bank-MB(a0)    * Numero de la banque
  3763.     move.l    d3,-(sp)
  3764. ; Get name to load
  3765. ; ~~~~~~~~~~~~~~~~
  3766.     move.l    (a3)+,a0
  3767.     move.w    (a0)+,d0
  3768.     subq.w    #1,d0    
  3769.     cmp.w    #128,d0
  3770.     Rbcc    L_IFonc
  3771.     move.l    Name1(a5),a1
  3772. .loop    move.b    (a0)+,(a1)+
  3773.     dbra    d0,.loop
  3774.     clr.b    (a1)
  3775.     Rjsr    L_Dsk.PathIt
  3776. ; Open the file
  3777. ; ~~~~~~~~~~~~~
  3778.     move.l    Name1(a5),d1
  3779.     move.l    #1005,d2
  3780.     move.l    a6,-(sp)
  3781.     move.l    DosBase(a5),a6
  3782.     jsr    -30(a6)            DosOpen, fichier sons
  3783.     move.l    (sp)+,a6
  3784.     move.l    d0,d7
  3785.     Rbeq    L_IDError
  3786.     move.l    d7,d1            Trouve la taille
  3787.     bsr    .taille
  3788.     move.l    d0,d6
  3789. ; Reserve the bank
  3790. ; ~~~~~~~~~~~~~~~~
  3791.     move.l    (sp)+,d0                Numero
  3792.     moveq    #(1<<Bnk_BitData+1<<Bnk_BitChip),d1    Flag
  3793.     move.l    d6,d2                    Taille
  3794.     lea    BkTrack(pc),a0                Nom
  3795.     Rjsr    L_Bnk.Reserve
  3796.     beq    .mem
  3797. ; Load the music
  3798. ; ~~~~~~~~~~~~~~
  3799.     move.l    d7,d1
  3800.     move.l    a0,d2
  3801.     move.l    d6,d3
  3802.     move.l    a6,-(sp)
  3803.     move.l    DosBase(a5),a6
  3804.     jsr    -42(a6)            Read
  3805.     move.l    (sp)+,a6
  3806.     move.l    d0,d2
  3807.     move.l    d7,d1
  3808.     bsr    .clo
  3809.     cmp.l    d2,d3
  3810.     Rbne    L_IFonc
  3811.     rts
  3812. * Close the file
  3813. .clo    movem.l    a6/a0/a1,-(sp)
  3814.     move.l    DosBase(a5),a6
  3815.     jsr    -36(a6)            Close
  3816.     movem.l    (sp)+,a6/a0/a1
  3817.     rts
  3818. * Out of memory
  3819. .mem    move.l    d7,d1
  3820.     bsr.s    .clo
  3821.     RBra    L_IOOMem
  3822. * Find the size of the file
  3823. .taille    move.l    a6,-(sp)
  3824.     move.l    d1,-(sp)
  3825.     moveq    #0,d2
  3826.     moveq    #1,d3
  3827.     move.l    DosBase(a5),a6
  3828.     jsr    -66(a6)            DosSeek
  3829.     move.l    (sp)+,d1
  3830.     move.l    d0,d2
  3831.     moveq    #-1,d3
  3832.     move.l    DosBase(a5),a6
  3833.     jsr    -66(a6)            DosSeek
  3834.     move.l    (sp)+,a6
  3835.     rts
  3836. BkTrack    dc.b    "Tracker "
  3837.     even
  3838.  
  3839. ******* TRACK CHECK, arrete la musique si pas banque...
  3840. L_TrackCheck    equ    89
  3841. L89    movem.l    a0-a1,-(sp)
  3842.     DLoad    a1
  3843.     tst.b    mt_on-MB(a1)
  3844.     beq.s    .skip
  3845.     move.l    mt_data-MB(a1),a0
  3846.     cmp.l    #"ker ",-(a0)
  3847.     bne.s    .stop
  3848.     cmp.l    #"Trac",-(a0)
  3849.     beq.s    .skip
  3850. .stop    RBsr    L_TrackStop
  3851. .skip    movem.l    (sp)+,a0-a1
  3852.     rts
  3853.  
  3854. ******* TRACK STOP
  3855. L_TrackStop    equ    90
  3856. L90    move.l    a0,-(sp)
  3857.     Dload    a0
  3858.     tst.b    mt_on-MB(a0)
  3859.     beq.s    .Skip
  3860.     clr.b    mt_on-MB(a0)
  3861.     moveq    #0,d0
  3862.     lea    $dff000,a0
  3863.     move.w    d0,$a8(a0)
  3864.     move.w    d0,$b8(a0)
  3865.     move.w    d0,$c8(a0)
  3866.     move.w    d0,$d8(a0)
  3867.     move.w    #$f,$dff096
  3868. .Skip    move.l    (sp)+,a0
  3869.     rts
  3870.  
  3871. ******* TRACK LOOP ON/OFF
  3872. L_TrackLoopon    equ    91
  3873. L91    rts
  3874. L_TrackLoopof    equ    92
  3875. L92    rts
  3876.  
  3877. ******* TRACK PLAY [Bank],[Pattern]
  3878.  
  3879. L_TrackPlay0    equ    93
  3880. L93
  3881.     move.l    #Entnul,-(a3)
  3882.     Rbra    94
  3883.  
  3884. L_TrackPlay1    equ    94
  3885. L94    
  3886.     move.l    #Entnul,-(a3)
  3887.     Rbra    95
  3888.  
  3889. L_TrackPlay2    equ    95
  3890. L95    
  3891.     move.l    (a3)+,d7
  3892.     cmp.l    #Entnul,(a3)
  3893.     bne.s    .skip
  3894.     Dload    a0
  3895.     moveq    #0,d0
  3896.     move.w    Track_Bank-MB(a0),d0
  3897.     move.l    d0,(a3)
  3898. .skip    
  3899.     move.l    (a3)+,d0
  3900.     Rjsr    L_Bnk.OrAdr
  3901.     move.l    d0,a2
  3902.     cmp.l    #"Trac",-8(a2)    
  3903.     bne    .nobank
  3904.     cmp.l    #"ker ",-4(a2)
  3905.     bne    .nobank
  3906.     
  3907.     Rbsr    L_SamStop0
  3908.     Rbsr    L_TrackStop
  3909.     
  3910. ; Init music...
  3911. ; ~~~~~~~~~~~~~
  3912.     move.l    a3,-(sp)
  3913.     Dload    a3
  3914.     move.l    a2,a0
  3915.     move.l    a0,mt_data-MB(a3)
  3916.     lea    mt_mulu-MB(a3),a1
  3917.     moveq    #$0c,d0
  3918.     add.l    a0,d0
  3919.     moveq    #$1f,d1
  3920.     moveq    #$1e,d3
  3921. .lop4    move.l    d0,(a1)+
  3922.     add.l    d3,d0
  3923.     dbf    d1,.lop4
  3924.  
  3925.     lea    $3b8(a0),a1
  3926.     moveq    #$7f,d0
  3927.     moveq    #0,d1
  3928.     moveq    #0,d2
  3929. .lop2    move.b    (a1)+,d1
  3930.     cmp.b    d2,d1
  3931.     ble.s    .lop
  3932.     move.l    d1,d2
  3933. .lop    dbf    d0,.lop2
  3934.     addq.w    #1,d2
  3935.  
  3936.     asl.l    #8,d2
  3937.     asl.l    #2,d2
  3938.     lea    4(a1,d2.l),a2
  3939.     lea    mt_samplestarts-MB(a3),a1
  3940.     add.w    #$2a,a0
  3941.     moveq    #$1e,d0
  3942. .lop3    clr.l    (a2)
  3943.     move.l    a2,(a1)+
  3944.     moveq    #0,d1
  3945.     move.b    d1,2(a0)
  3946.     move.w    (a0),d1
  3947.     asl.l    #1,d1
  3948.     add.l    d1,a2
  3949.     add.l    d3,a0
  3950.     dbf    d0,.lop3
  3951.  
  3952.     move.b    #6,mt_speed-mt_samplestarts-$7c(a1)
  3953.     moveq    #0,d0
  3954.     lea    $dff000,a0
  3955.     move.w    d0,$a8(a0)
  3956.     move.w    d0,$b8(a0)
  3957.     move.w    d0,$c8(a0)
  3958.     move.w    d0,$d8(a0)
  3959.     move.b    d0,mt_songpos-mt_samplestarts-$7c(a1)
  3960.     move.b    d0,mt_counter-mt_samplestarts-$7c(a1)
  3961.     move.w    d0,mt_pattpos-mt_samplestarts-$7c(a1)
  3962.  
  3963. ; Demarage de la musique!
  3964. ; ~~~~~~~~~~~~~~~~~~~~~~~
  3965.     move.b    #1,mt_on-MB(a3)
  3966.     move.l    (sp)+,a3    
  3967.     rts
  3968. * Pas un module tracker
  3969. .nobank    moveq    #8,d0
  3970.     Rbra    L_Custom
  3971.  
  3972. ******* Erreur disque
  3973. L_IDError    equ    96
  3974. L96    move.w    #DEBase+15,d0
  3975.     Rjmp    L_Error
  3976.  
  3977. ******* Routine, demande la bouche du narrator
  3978. L_Lips        equ    97
  3979. L97    Dload    a2
  3980.     tst.l    TranBase-MB(a2)
  3981.     beq.s    .Err
  3982.     move.l    WriteIo-MB(a2),d0
  3983.     beq.s    .Err
  3984.     move.l    d0,a0
  3985.     tst.b    66(a0)
  3986.     beq.s    .Err
  3987.     lea    ReadIo-MB(a2),a1
  3988.     move.w    #2,28(a1)            CMD_READ
  3989.     move.l    a6,-(sp)
  3990.     move.l    $4.w,a6
  3991.     jsr    DoIO(a6)
  3992.     move.l    (sp)+,a6
  3993.     lea    ReadIo-MB(a2),a1
  3994.     cmp.b    #-8,$1f(a1)            ND_NOWRITE
  3995.     beq.s    .Err
  3996.     rts
  3997. .Err    lea    ReadIo-MB(a2),a0
  3998.     move.w    #-1,88(a0)
  3999.     rts
  4000.  
  4001. *********************************************************************
  4002. *    AMIGA.LIB linked code. 
  4003. *    In order to make it relocatable, I have been
  4004. *    obliged to disassemble the code and include it in this 
  4005. *    routine.
  4006. L_Amiga.Lib    equ    98
  4007. L98    lsl.w    #2,d0
  4008.     lea    JJJmp(pc),a0
  4009.     jmp    0(a0,d0.w)
  4010. JJJmp    bra    _CreatePort
  4011.     bra    _DeletePort
  4012.     bra    _CreateExtIO
  4013.     bra    _DeleteExtIO
  4014.  
  4015. _CreatePort
  4016.     MOVEM.L    D2-7/A2,-(A7)
  4017.     MOVE.L    $20(A7),D4
  4018.     MOVE.B    $27(A7),D3
  4019.     MOVE.L    #$FFFFFFFF,-(A7)
  4020.     BSR    L7C7DB14
  4021.     MOVE.L    D0,D5
  4022.     MOVE.L    D5,D6
  4023.     MOVEQ    #-1,D2
  4024.     CMP.L    D5,D2
  4025.     ADDQ.L    #4,A7
  4026.     BNE.S    L7C7D97A
  4027.     MOVEQ    #0,D0
  4028.     BRA    L7C7D9E6
  4029. L7C7D97A    MOVE.L    #$10001,-(A7)
  4030.     PEA    $22.W
  4031.     BSR    L7C7DAD0
  4032.     MOVEA.L    D0,A2
  4033.     EXG    D7,A2
  4034.     TST.L    D7
  4035.     EXG    D7,A2
  4036.     ADDQ.L    #8,A7
  4037.     BNE.S    L7C7D9A4
  4038.     MOVE.L    D6,-(A7)
  4039.     BSR    L7C7DB28
  4040.     MOVEQ    #0,D0
  4041.     ADDQ.L    #4,A7
  4042.     BRA.S    L7C7D9E6
  4043. L7C7D9A4    MOVE.L    D4,$A(A2)
  4044.     MOVE.B    D3,9(A2)
  4045.     MOVE.B    #4,8(A2)
  4046.     CLR.B    $E(A2)
  4047.     MOVE.B    D6,$F(A2)
  4048.     CLR.L    -(A7)
  4049.     BSR    L7C7DB00
  4050.     MOVE.L    D0,$10(A2)
  4051.     TST.L    D4
  4052.     ADDQ.L    #4,A7
  4053.     BEQ.S    L7C7D9D8
  4054.     MOVE.L    A2,-(A7)
  4055.     BSR    L7C7DB3C
  4056.     ADDQ.L    #4,A7
  4057.     BRA.S    L7C7D9E4
  4058. L7C7D9D8    PEA    $14(A2)
  4059.     BSR    _NewList
  4060.     ADDQ.L    #4,A7
  4061. L7C7D9E4    MOVE.L    A2,D0
  4062. L7C7D9E6    MOVEM.L    (A7)+,D2-7/A2
  4063.     RTS
  4064.  
  4065. _DeletePort
  4066.     MOVEM.L    D2/A2,-(A7)
  4067.     MOVEA.L    $C(A7),A2
  4068.     TST.L    $A(A2)
  4069.     BEQ.S    L7C7DA04
  4070.     MOVE.L    A2,-(A7)
  4071.     BSR    L7C7DB50
  4072.     ADDQ.L    #4,A7
  4073. L7C7DA04    MOVE.B    #$FF,8(A2)
  4074.     MOVEQ    #-1,D2
  4075.     MOVE.L    D2,$14(A2)
  4076.     MOVEQ    #0,D2
  4077.     MOVE.B    $F(A2),D2
  4078.     MOVE.L    D2,-(A7)
  4079.     BSR    L7C7DB28
  4080.     PEA    $22.W
  4081.     MOVE.L    A2,-(A7)
  4082.     BSR    L7C7DAE8
  4083.     LEA    $C(A7),A7
  4084.     MOVEM.L    (A7)+,D2/A2
  4085.     RTS
  4086. _CreateExtIO
  4087.     MOVEM.L    D2-4,-(A7)
  4088.     MOVE.L    $10(A7),D2
  4089.     MOVE.L    $14(A7),D3
  4090.     TST.L    D2
  4091.     BNE.S    L7C7DA54
  4092.     MOVEQ    #0,D0
  4093.     BRA.S    L7C7DA82
  4094. L7C7DA54    MOVE.L    #$10001,-(A7)
  4095.     MOVE.L    D3,-(A7)
  4096.     BSR    L7C7DAD0
  4097.     MOVEA.L    D0,A0
  4098.     EXG    D4,A0
  4099.     TST.L    D4
  4100.     EXG    D4,A0
  4101.     ADDQ.L    #8,A7
  4102.     BNE.S    L7C7DA72
  4103.     MOVEQ    #0,D0
  4104.     BRA.S    L7C7DA82
  4105. L7C7DA72    MOVE.B    #5,8(A0)
  4106.     MOVE.W    D3,$12(A0)
  4107.     MOVE.L    D2,$E(A0)
  4108.     MOVE.L    A0,D0
  4109. L7C7DA82    MOVEM.L    (A7)+,D2-4
  4110.     RTS
  4111.  
  4112. _DeleteExtIO
  4113.     MOVEM.L    D2-3,-(A7)
  4114.     MOVEA.L    $C(A7),A0
  4115.     EXG    D3,A0
  4116.     TST.L    D3
  4117.     EXG    D3,A0
  4118.     BEQ    L7C7DABE
  4119.     MOVE.B    #$FF,8(A0)
  4120.     MOVEQ    #-1,D2
  4121.     MOVE.L    D2,$14(A0)
  4122.     MOVEQ    #-1,D2
  4123.     MOVE.L    D2,$18(A0)
  4124.     MOVEQ    #0,D2
  4125.     MOVE.W    $12(A0),D2
  4126.     MOVE.L    D2,-(A7)
  4127.     MOVE.L    A0,-(A7)
  4128.     BSR    L7C7DAE8
  4129.     ADDQ.L    #8,A7
  4130. L7C7DABE    MOVEM.L    (A7)+,D2-3
  4131.     RTS
  4132. L7C7DAD0
  4133.     MOVE.L    A6,-(A7)
  4134.     MOVEA.L    $4.w,A6
  4135.     MOVEM.L    8(A7),D0-1
  4136.     JSR    -$C6(A6)
  4137.     MOVEA.L    (A7)+,A6
  4138.     RTS
  4139. L7C7DAE8
  4140.     MOVE.L    A6,-(A7)
  4141.     MOVEA.L    $4.w,A6
  4142.     MOVEA.L    8(A7),A1
  4143.     MOVE.L    $C(A7),D0
  4144.     JSR    -$D2(A6)
  4145.     MOVEA.L    (A7)+,A6
  4146.     RTS
  4147. L7C7DB00
  4148.     MOVE.L    A6,-(A7)
  4149.     MOVEA.L    $4.w,A6
  4150.     MOVEA.L    8(A7),A1
  4151.     JSR    -$126(A6)
  4152.     MOVEA.L    (A7)+,A6
  4153.     RTS
  4154. L7C7DB14
  4155.     MOVE.L    A6,-(A7)
  4156.     MOVEA.L    $4.w,A6
  4157.     MOVE.L    8(A7),D0
  4158.     JSR    -$14A(A6)
  4159.     MOVEA.L    (A7)+,A6
  4160.     RTS
  4161. L7C7DB28
  4162.     MOVE.L    A6,-(A7)
  4163.     MOVEA.L    $4.w,A6
  4164.     MOVE.L    8(A7),D0
  4165.     JSR    -$150(A6)
  4166.     MOVEA.L    (A7)+,A6
  4167.     RTS
  4168. L7C7DB3C
  4169.     MOVE.L    A6,-(A7)
  4170.     MOVEA.L    $4.w,A6
  4171.     MOVEA.L    8(A7),A1
  4172.     JSR    -$162(A6)
  4173.     MOVEA.L    (A7)+,A6
  4174.     RTS
  4175. L7C7DB50
  4176.     MOVE.L    A6,-(A7)
  4177.     MOVEA.L    $4.w,A6
  4178.     MOVEA.L    8(A7),A1
  4179.     JSR    -$168(A6)
  4180.     MOVEA.L    (A7)+,A6
  4181.     RTS
  4182. _NewList
  4183.     move.l    4(a7),a0
  4184.     move.l    a0,(a0)
  4185.     addq.l    #4,(a0)
  4186.     clr.l    4(a0)
  4187.     move.l    a0,8(a0)
  4188.     rts
  4189.  
  4190. ******* TALK MISC volume,freq
  4191. L_TalkMisc        equ    99
  4192. L99    Rbsr    L_OpNar
  4193.     move.l    #EntNul,d0
  4194.     Dload    a1
  4195.     move.l    WriteIo-MB(a1),a1
  4196.     move.l    (a3)+,d1
  4197.     cmp.l    d0,d1
  4198.     beq.s    .IRd0
  4199.     cmp.w    #5000,d1
  4200.     Rbcs    L_IFonc
  4201.     cmp.w    #25000,d1
  4202.     Rbhi    L_IFonc
  4203.     move.w    d1,64(a1)
  4204. .IRd0
  4205.     move.l    (a3)+,d1
  4206.     cmp.l    d0,d1
  4207.     beq.s    .IRd1
  4208.     tst.l    d1
  4209.     RBmi    L_IFonc
  4210.     cmp.w    #64,d1
  4211.     Rbhi    L_IFonc
  4212.     move.w    d1,62(a1)
  4213. .IRd1
  4214.     rts
  4215.  
  4216. *********************************************************************
  4217. *    SSAVE fichier,adresse To fin
  4218. L_SSave        equ    100
  4219. L100    move.l    (a3)+,d3        End adress
  4220.     move.l    (a3)+,d2        Start Adress
  4221.     sub.l    d2,d3
  4222.     RBle    L_IFonc
  4223.     move.l    (a3)+,d0        File
  4224.     cmp.l    #10,d0
  4225.     Rbcc    L_IFonc
  4226.     subq.l    #1,d0
  4227.     Rbmi    L_IFonc
  4228.     mulu    #TFiche,d0
  4229.     lea    Fichiers(a5),a2
  4230.     add.w    d0,a2
  4231.     move.l    Fha(a2),d1
  4232.     Rbeq    L_IFonc
  4233.     btst    #2,FhT(a2)
  4234.     Rbne    L_IFonc
  4235. * Save the data
  4236.     move.l    a6,-(sp)
  4237.     move.l    DosBase(a5),a6
  4238.     jsr    _LVOWrite(a6)
  4239.     move.l    (sp)+,a6
  4240.     tst.l    d0
  4241.     RBmi    L_IDError
  4242.     rts
  4243.  
  4244.  
  4245. ; ___________________________________________________________________
  4246. ;
  4247. ;    MED instructions
  4248. ; ___________________________________________________________________
  4249.  
  4250. ;    MED LOAD "nom",banque
  4251. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  4252. L_MedLoad    equ    101
  4253. L101    Rbsr    L_MedOpen
  4254.     move.l    (a3)+,d3
  4255.     cmp.l    #$10000,d3
  4256.     Rbge    L_IFonc
  4257.     Dload    a2
  4258.     cmp.w    Med_Bank-MB(a2),d3
  4259.     bne.s    .k
  4260.     Rbsr    L_MedStop
  4261. .k    move.w    d3,Med_Bank-MB(a2)    * Numero de la banque
  4262. ; Get name to load
  4263. ; ~~~~~~~~~~~~~~~~
  4264.     move.l    (a3)+,a0
  4265.     move.w    (a0)+,d0
  4266.     subq.w    #1,d0    
  4267.     cmp.w    #128,d0
  4268.     Rbcc    L_IFonc
  4269.     move.l    Name1(a5),a1
  4270. .loop    move.b    (a0)+,(a1)+
  4271.     dbra    d0,.loop
  4272.     clr.b    (a1)
  4273.     Rjsr    L_Dsk.PathIt
  4274. ; Trouve la taille
  4275. ; ~~~~~~~~~~~~~~~~
  4276.     move.l    Name1(a5),d1
  4277.     move.l    #1005,d2
  4278.     move.l    a6,-(sp)
  4279.     move.l    DosBase(a5),a6
  4280.     jsr    -30(a6)            DosOpen,
  4281.     move.l    (sp)+,a6
  4282.     move.l    d0,d7
  4283.     Rbeq    L_IDError
  4284.     move.l    d7,d1            Trouve la taille
  4285.     bsr    .taille
  4286.     move.l    d0,d6
  4287. ; Reserve la banque
  4288. ; ~~~~~~~~~~~~~~~~~
  4289.     move.w    Med_Bank-MB(a2),d0            Numero de la banque
  4290.     ext.l    d0
  4291.     moveq    #(1<<Bnk_BitChip),d1            Flag CHIP
  4292.     move.l    d6,d2
  4293.     addq.l    #8,d2                    Taille
  4294.     lea    .BkMed(pc),a0                Nom
  4295.     Rjsr    L_Bnk.Reserve
  4296.     beq    .mem
  4297.     move.l    a0,a2
  4298. ; Charge la musique
  4299. ; ~~~~~~~~~~~~~~~~~
  4300.     move.l    d7,d1
  4301.     move.l    a2,d2
  4302.     move.l    d6,d3
  4303.     move.l    a6,-(sp)
  4304.     move.l    DosBase(a5),a6
  4305.     jsr    -42(a6)            Read
  4306.     move.l    (sp)+,a6
  4307.     move.l    d0,d2
  4308.     move.l    d7,d1
  4309.     bsr    .clo
  4310.     cmp.l    d2,d3
  4311.     Rbne    L_IFonc
  4312.     cmp.l    #"MMD0",(a2)
  4313.     beq.s    .ok
  4314.     cmp.l    #"MMD1",(a2)
  4315.     bne.s    .med
  4316. ; Relocation du module
  4317. ; ~~~~~~~~~~~~~~~~~~~~
  4318. .ok    move.l    a6,-(sp)
  4319.     Dload    a0
  4320.     move.l    Med_Base-MB(a0),a6
  4321.     move.l    a2,a0
  4322.     jsr    _MEDRelocModule(a6)
  4323.     move.l    (sp)+,a6
  4324.     rts
  4325. * Ferme le fichier
  4326. .clo    movem.l    a6/a0/a1,-(sp)
  4327.     move.l    DosBase(a5),a6
  4328.     jsr    -36(a6)            Close
  4329.     movem.l    (sp)+,a6/a0/a1
  4330.     rts
  4331. * Out of memory
  4332. .mem    move.l    d7,d1
  4333.     beq.s    .xx
  4334.     bsr.s    .clo
  4335. .xx    Rbra    L_IOOMem
  4336. * Not a MED file
  4337. .med    Dlea    Med_Bank,a0
  4338.     move.w    (a0),d0
  4339.     ext.l    d0
  4340.     Rjsr    L_Bnk.Eff
  4341.     move.w    #189,d0
  4342.     Rjmp    L_Error
  4343. * Routine, trouve la taille d'un fichier
  4344. .taille    move.l    a6,-(sp)
  4345.     move.l    d1,-(sp)
  4346.     moveq    #0,d2
  4347.     moveq    #1,d3
  4348.     move.l    DosBase(a5),a6
  4349.     jsr    -66(a6)            DosSeek
  4350.     move.l    (sp)+,d1
  4351.     move.l    d0,d2
  4352.     moveq    #-1,d3
  4353.     move.l    DosBase(a5),a6
  4354.     jsr    -66(a6)            DosSeek
  4355.     move.l    (sp)+,a6
  4356.     rts
  4357. .BkMed    dc.b    "Med     "
  4358.     even
  4359.  
  4360. ;    MED CHECK, arrete la musique si pas banque...
  4361. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  4362. L_MedCheck    equ    102
  4363. L102    movem.l    d0/a0-a1,-(sp)
  4364.     DLoad    a1
  4365.     tst.b    Med_On-MB(a1)
  4366.     beq.s    .skip
  4367.     move.l    Med_Adr-MB(a1),d0
  4368.     beq.s    .skip
  4369.     move.l    d0,a0
  4370.     cmp.l    #"Med ",-(a0)
  4371.     bne.s    .stop
  4372.     cmp.l    #"    ",-(a0)
  4373.     beq.s    .skip
  4374. .stop    Rbsr    L_MedStop
  4375.     clr.l    Med_Adr-MB(a1)
  4376. .skip    movem.l    (sp)+,d0/a0-a1
  4377.     rts
  4378.  
  4379. ;    MED STOP
  4380. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  4381. L_MedStop    equ    103
  4382. L103    movem.l    a0-a2/a6/d0-d2,-(sp)
  4383.     Dload    a0
  4384.     tst.b    Med_On-MB(a0)
  4385.     beq.s    .NoMed
  4386.     clr.b    Med_On-MB(a0)
  4387.     move.l    Med_Base-MB(a0),a6
  4388.     jsr    _MEDStopPlayer(a6)
  4389. .NoMed    movem.l    (sp)+,a0-a2/a6/d0-d2
  4390.     rts
  4391.  
  4392. ;    MED PLAY [Bank],[Song]
  4393. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  4394. L_MedPlay0    equ    104
  4395. L104    move.l    #EntNul,-(a3)
  4396.     Rbra    L_MedPlay1
  4397. L_MedPlay1    equ    105
  4398. L105    move.l    #EntNul,-(a3)
  4399.     Rbra    L_MedPlay2
  4400. L_MedPlay2    equ    106
  4401. L106    Dload    a2            Arret d'une eventuelle musique
  4402.     Rbsr    L_MedOpen        Ouvre la librairie, s'il faut
  4403.     Rbsr    L_MedStop
  4404.     clr.l    Med_Adr-MB(a2)
  4405. ; Verification de la banque
  4406. ; ~~~~~~~~~~~~~~~~~~~~~~~~~
  4407.     move.l    (a3)+,d7
  4408.     cmp.l    #Entnul,(a3)
  4409.     bne.s    .skip
  4410.     moveq    #0,d0
  4411.     move.w    Med_Bank-MB(a2),d0
  4412.     move.l    d0,(a3)
  4413. .skip    move.l    (a3)+,d0
  4414.     Rjsr    L_Bnk.OrAdr
  4415.     move.l    d0,a2
  4416.     cmp.l    #"Med ",-8(a2)    
  4417.     bne    .nobank
  4418.     cmp.l    #"    ",-4(a2)
  4419.     bne    .nobank
  4420.     
  4421. ; Arret de tous les sons...
  4422. ; ~~~~~~~~~~~~~~~~~~~~~~~~~
  4423.     Rbsr    L_SamStop0
  4424.     Rbsr    L_TrackStop
  4425.     Rbsr    L_MedStop
  4426. ; Pointe la chanson
  4427. ; ~~~~~~~~~~~~~~~~~
  4428.     movem.l    a3/a6,-(sp)
  4429.     Dload    a3
  4430.     moveq    #0,d0
  4431.     cmp.l    #Entnul,d7
  4432.     beq.s    .skp
  4433.     move.l    d7,d0
  4434. .skp    move.l    Med_Base-MB(a3),a6
  4435.     jsr    _MEDSetModnum(a6)
  4436. ; Demarre la chanson
  4437. ; ~~~~~~~~~~~~~~~~~~
  4438.     move.l    a2,a0
  4439.     jsr    _MEDPlayModule(a6)
  4440.     move.l    a2,Med_Adr-MB(a3)
  4441.     move.b    #1,Med_On-MB(a3)
  4442. ; Terminé
  4443. ; ~~~~~~~
  4444.     movem.l    (sp)+,a3/a6
  4445.     rts
  4446. ; Pas une banque MED
  4447. ; ~~~~~~~~~~~~~~~~~~
  4448. .nobank    moveq    #8,d0
  4449.     Rbra    L_Custom
  4450.  
  4451. ;     Ouvre la librairie MED
  4452. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  4453. L_MedOpen    equ    107
  4454. L107    movem.l    a0-a2/d0-d2,-(sp)
  4455.     Dload    a2
  4456.     tst.l    Med_Base-MB(a2)
  4457.     bne.s    .Open
  4458.     lea    Med_Name-MB(a2),a1
  4459.     moveq    #2,d0            2 et pas 3!!!!!!!!!!!!!!!!!!!!
  4460.     move.l    a6,-(sp)
  4461.     move.l    $4.w,a6
  4462.     jsr    _LVOOpenLibrary(a6)
  4463.     move.l    (sp)+,a6
  4464.     move.l    d0,Med_Base-MB(a2)
  4465.     beq.s    .Err1
  4466.     moveq    #0,d0
  4467.     move.b    Med_Midi-MB(a2),d0
  4468.     move.l    a6,-(sp)
  4469.     move.l    Med_Base-MB(a2),a6
  4470.     jsr    _MEDGetPlayer(a6)
  4471.     move.l    (sp)+,a6
  4472.     tst.l    d0
  4473.     bne    .Err2
  4474. .Open    movem.l    (sp)+,a0-a2/d0-d2
  4475.     rts
  4476. .Err1    move.w    #187,d0            Cannot load med.lib
  4477.     Rjmp    L_Error
  4478. .Err2    Rbsr    L_MedClose        Cannot initialise med.lib
  4479.     move.w    #188,d0
  4480.     Rjmp    L_Error    
  4481.  
  4482. ;    MED MIDI ON / OFF
  4483. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  4484. L_MedMidiOn    equ    108    
  4485. L108    Dlea    Med_Midi,a0
  4486.     move.b    #1,(a0)
  4487.     rts
  4488. L109
  4489.  
  4490. ;    MED CLOSE
  4491. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  4492. L_MedClose    equ    110
  4493. L110    movem.l    a0-a2/a6/d0-d2,-(sp)
  4494.     Rbsr    L_MedStop
  4495.     Dload    a2
  4496.     clr.b    Med_Midi-MB(a2)
  4497.     clr.l    Med_Adr-MB(a2)
  4498.     move.l    Med_Base-MB(a2),d0
  4499.     beq.s    .Skip
  4500.     move.l    d0,a6
  4501.     jsr    _MEDFreePlayer(a6)
  4502.     move.l    Med_Base-MB(a2),a1
  4503.     clr.l    Med_Base-MB(a2)
  4504.     move.l    $4.w,a6
  4505.     jsr    _LVOCloseLibrary(a6)
  4506. .Skip    movem.l    (sp)+,a0-a2/a6/d0-d2
  4507.     rts
  4508.  
  4509. ;    MED CONT
  4510. ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  4511. L_MedCont    equ    111
  4512. L111    movem.l    a0-a2/a6/d0-d2,-(sp)
  4513.     Dload    a0
  4514.     move.l    Med_Adr-MB(a0),d0
  4515.     beq.s    .Skip
  4516.     tst.b    Med_On-MB(a0)
  4517.     bne.s    .Skip
  4518.     move.b    #1,Med_On-MB(a0)
  4519.     move.l    Med_Base-MB(a0),a6
  4520.     move.l    d0,a0
  4521.     jsr    _MEDContModule(a6)
  4522. .Skip    movem.l    (sp)+,a0-a2/a6/d0-d2
  4523.     rts
  4524.     
  4525.  
  4526. *********************************************************************
  4527. *    ERROR MESSAGES...
  4528. ;
  4529. ; You know that the compiler have a -E1 option (with errors) and a 
  4530. ; a -E0 (without errors). To achieve that, the compiler copies one of
  4531. ; the two next routines, depending on the -E flag. If errors are to be
  4532. ; copied along with the program, then the next next routine is used. If not,
  4533. ; then the next one is copied.
  4534. ; The compiler assumes that the two last routines in the library handles
  4535. ; the errors: the previous last is WITH errors, the last is WITHOUT. So,
  4536. ; remember:
  4537. ;
  4538. ; THESE ROUTINES MUST BE THE LAST ONES IN THE LIBRARY
  4539. ;
  4540. ; The AMOS interpretor always needs errors. So make all your custom errors
  4541. ; calls point to the L_Custom routine, and everything will work fine...
  4542. ;
  4543. ******* "With messages" routine.
  4544. ; The following routine is the one your program must call to output
  4545. ; a extension error message. It will be used under interpretor and under
  4546. ; compiled program with -E1
  4547.  
  4548. L_Custom    equ    112
  4549. L112    lea    ErrMess(pc),a0
  4550.     moveq    #0,d1            * Can be trapped
  4551.     moveq    #ExtNb,d2        * Number of extension
  4552.     moveq    #0,d3            * IMPORTANT!!!
  4553.     RJmp    L_ErrorExt        * Jump to routine...
  4554. * Messages...
  4555. ErrMess    dc.b    "Wave not defined",0            *0
  4556.     dc.b     "Sample not defined",0            *1
  4557.     dc.b     "Sample bank not found",0        *2
  4558.     dc.b    "256 characters for a wave",0        *3
  4559.     dc.b    "Wave 0 and 1 are reserved",0        *4
  4560.     dc.b    "Music bank not found",0        *5
  4561.     dc.b     "Music not defined",0            *6
  4562.     dc.b    "Can't open narrator",0            *7
  4563.     dc.b    "Not a tracker module",0        *8
  4564. * IMPORTANT! Always EVEN!
  4565.     even
  4566.  
  4567. ******* "No errors" routine
  4568. ; If you compile with -E0, the compiler will replace the previous
  4569. ; routine by this one. This one just sets D3 to -1, and does not
  4570. ; load messages in A0. Anyway, values in D1 and D2 must be valid.
  4571. ;    
  4572. ; THIS ROUTINE MUST BE THE LAST ONE IN THE LIBRARY!
  4573. ;
  4574.  
  4575. L113    moveq    #0,d1
  4576.     moveq    #ExtNb,d2
  4577.     moveq    #-1,d3
  4578.     RJmp    L_ErrorExt
  4579.  
  4580. ; Do not forget the last label to delimit the last library routine!
  4581. L114
  4582.  
  4583. ; ---------------------------------------------------------------------
  4584. ; Now the title of the extension, just the string.
  4585. ;
  4586. ; TITLE MESSAGE
  4587. C_Title    dc.b    "AMOSPro Music extension V "
  4588.     Version
  4589.     dc.b    0,"$VER: "
  4590.     Version
  4591.     dc.b    0
  4592.     Even
  4593. ; 
  4594. ; Note : magic title!
  4595. ; ~~~~~~~~~~~~~~~~~~~
  4596. ; If your extension begins with "MAGIC***", AMOSPro will call the 
  4597. ; address located after the string (even of course!). You can do whatever
  4598. ; you want to the editor screen (the current at the moment), but
  4599. ; restore it.
  4600. ; You also handle the user key press, and the PREVIOUS/NEXT/CANCEL
  4601. ; selection, buy returning a number in D0:
  4602. ;    D0=-1    Cancel
  4603. ;    D0=0    Previous extension
  4604. ;    D0=1    Next extension
  4605. ; Example of magic title:
  4606. ;    C_Title        dc.b    "MAGIC***"
  4607. ;            bra    Magic_Title
  4608.  
  4609.  
  4610. ; END OF THE EXTENSION
  4611. C_End    dc.w    0
  4612.     even
  4613.  
  4614.  
  4615.